!==========================================================
Constant Story "Châtiment divin";
Constant Headline
"^Un jeu par Hugo Labrande^2èmes Rapid'Fictions du 26 août 2007^";
Release 2; Serial "290807";
Constant MAX_SCORE=20;
Global scarab=0;
Global joug=0;
Global tour=0;
Global pri=0;
Include "Parser";
Include "VerbLib";
!==========================================================
! Routine
[ w8 notNeeded;
@read_char 1 notNeeded;
rtrue;
];
!==========================================================
! Objets et lieux
Object eglise "Dans l'église"
with description "Vous êtes dans l'église de votre petite ville, l'église Saint-François, une grande église gothique du XIVème siècle. Les vieilles pierres gardent l'église au frais, mais vous voyez au-dehors et à travers les vitraux un soleil radieux ; il devrait faire chaud en sortant de l'église... Vous suivez la messe depuis son commencement ; à l'heure actuelle, l'abbé Costicela dit son sermon, et vous l'écoutez avec attention, assis en face de votre pupitre, de même que les autres fidèles assis à vos côtés sur les bancs de l'église.",
before [; Listen: "L'assemblée de fidèles est silencieuse, et écoute le sermon du prêtre.";
],
out_to [; if (score==0) {"Non, pourquoi sortir en plein milieu de la messe ?";} else {print "Vous sortez de l'église en silence, bien que certains vous remarquent. Pas le temps de leur expliquer. L'abbé Costicela s'interrompt quelques secondes en vous voyant : c'est bien la première fois qu'il vous voit quitter une messe en plein milieu..."; w8(); print "^^Une fois dehors, le coeur battant, vous vous dépêchez : prenant votre vélo, vous vous rendez au 26, rue de la République en quatrième vitesse..."; w8(); print "^^Vous y arrivez, enfin. Il s'agit de la boutique d'un prêteur sur gages - le djinn avait raison, c'est exactement dans ce genre de lieux qu'on peut s'attendre à voir un sabre...^^Vous attachez votre vélo, pour ne pas vous le faire voler, puis traversez la rue, et poussez la porte du prêteur sur gages.^"; return preteur;}
],
has ;
Object orgue "orgue" eglise
with description "L'orgue de votre église, un très bel orgue à tuyaux, assez ancien. Vous êtes en train d'apprendre à en jouer - vous êtes tellement habitué à ce son que vous avez tout naturellement cherché à apprendre à en jouer, et vous vous révelez être un plutôt bon élève.",
name 'orgue' 'tuyaux',
has scenery ;
Object vitro "vitraux" eglise
with description "Les vitraux de l'église, qui ont été rénovés il y a peu. Ils laissent passer la lumière éclatante du jour, éclairant les scènes qu'ils représentent d'une vivre lueur.",
name 'vitraux' 'vitres',
before [; Take, Push, Pull: "Ils sont trop hauts pour que vous puissiez leur faire quoi que ce soit. De toute façon, vous auriez trop peur de casser ces beaux vitraux.";
],
has pluralname concealed;
Object siege "sièges" eglise
with description "Ce sont les bancs de l'église, en bois ; ils ont apparemment été cirés il y a peu.",
name 'sièges' 'bancs',
has supporter pluralname scenery ;
Object pupitre "pupitre" eglise
with description "Il s'agit du pupitre en face de vous ; c'est un simple pupitre en bois, et vous y avez posé votre missel.",
name 'pupitre',
has scenery supporter concealed;
Object missel "missel" pupitre
with description "C'est votre vieux missel, celui que vos parents vous ont offert quand vous aviez dix ans. Il est vieux, il a une couverture bleue, mais vous ne vous en séparez quasiment jamais.",
name 'missel' 'bible' 'livre' 'vieux',
before [; Take: "Non, on ne sait jamais, vous pourriez en avoir besoin plus tard pendant la messe.";
lir: "Non, ça ne sert à rien - vous le connaissez presque par coeur, mais l'intérêt d'une messe, c'est d'être avec les autres, pas de lire dans son coin... Alors écoutons plutôt le curé.";
Close: if (scarab<5) {"Ca ne servirait à rien, vous allez devoir l'ouvrir au nouveau pendant la messe...";} else {print "Tout en guettant le scarabée, vous approchez lentement votre main gauche de votre missel. Le scarabée, occupé à se nettoyer les pattes, ne semble rien remarquer, et n'esquisse pas un mouvement. Vous prenez la moitié gauche du missel, en retenant votre souffle. Votre missel risque d'être taché du sang de ce scarabée, mais vous n'en avez cure - le missel en a déjà tellement vu... Vous demandez mentalement pardon au Tout-Puissant d'avoir à tuer l'une de ses créatures, mais tout en sachant que ce meurtre ne vous vaudra pas l'enfer. Soudain, d'un coup sec, vous refermez le missel. Le scarabée n'a pas vu venir la couverture, et n'a pas le temps de s'envoler : il se fait écraser par le missel. Avec un soupir de contentement face à l'élimination de ce gêneur, vous appuyez encore un peu plus afin de bien être sûr d'avoir écrasé le scarabée, puis vous ouvrez le missel."; w8(); print "^^Le scarabée est là, tout écrabouillé, aplati, agitant spasmodiquement ses pattes. Votre missel est un peu taché de sang de scarabée, mais c'était pour la bonne cause. Il a en quelque sorte été tué par la parole divine, par la main de Dieu, pensez-vous non sans ironie. Vous prenez votre missel et le secouez pour en faire tomber le cadavre du scarabée dans l'allée. Puis, pas plus troublé que ça, vous vous concentrez à nouveau sur le sermon du prêtre."; w8(); print "^^Quelques heures plus tard, par votre faute, un astéroïde percute la Terre.^^"; w8(); deadflag=1;}
],
has openable open concealed ;
Object scarabee "scarabée" eglise
with description "C'est un gros scarabée noir, avec une grosse carapace luisante. Un gros insecte, plutôt moche pas très ragoûtant - mais les insectes sont aussi des créatures de Dieu, vous dites-vous...",
name 'scarabee' 'bete' 'insecte',
before [; chass, Attack: scarab=0; "Vous approchez votre main de ce scarabée énervant pour l'écraser, mais celui-ci s'envole avant que vous puissiez l'attraper, pour finalement se poser à nouveau sur le pupitre.";
Tell: scaratalk(); rtrue;
],
daemon [k;
if (scarab<17) {scarab++;}
if (location==eglise){
switch(scarab){
0: print "Un scarabée est sur le pupitre, apparemment pas plus effrayé que ça par votre présence.";
1: print "Le scarabée se rapproche un peu de vous, sondant l'air de ses antennes.";
2: print "Le scarabée est maintenant tout près de votre main. La présence d'humains n'a pas l'air de le gêner outre mesure.";
3: print "Le scarabée est en face de vous, sur le haut de votre pupitre. Vous seriez prêt à parier qu'il vous regarde, bizarrement...";
4: print "Le scarabée agite les antennes et se dresse sur ses pattes arrières. Bizarre, même très bizarre, pour un scarabée.";
5: print "Le scarabée est sur votre missel ouvert. A y regarder de plus près, on dirait qu'il bave sur le papier, une bave noirâtre peu ragoûtante. Beurk.";
6: print "Le scarabée a bavé sur la marge de votre missel, selon un motif qui vous semble chaotique. Mais bizarrement, ce motif a l'air cohérent, des volutes, des traits, des points... On dirait presque des caractères arabes, que vous avez pris pour chaotiques car vous êtes plus habitué au latin qu'à l'arabe littéraire... Mais c'est impossible : les scarabées ne sont pas musulmans, enfin ! Vous chassez ces divagations, qui vous distraient du bon déroulement de la messe.";
7: print "Le scarabée s'est dressé une fois de plus sur ses pattes arrière, et agite ses pattes avant.";
8: print "Le scarabée est sur l'autre page de votre missel ouvert. Il est encore en train de baver.";
9: print "Le scarabée est sur l'autre page de votre missel ouvert, en train de répandre sa bave noirâtre, selon des motifs plus rectilignes - mais ça reste de la bave de scarabée. Beurk.";
10: print "Le scarabée bave encore sur la page de votre missel. Mais vous regardez, incrédule, le motif qu'il est en train de tracer : on dirait des lettres ! Mais c'est impossible, irrationnel, vous dites-vous : c'est du pur hasard, c'est tout...";
11: print "Le scarabée est sur ses pattes arrière, et agite ses pattes avant. Vous regardez le motif qu'il a tracé : ce sont bien des lettres ! Vos yeux s'écarquillent d'étonnement : le scarabée a écrit en lettres capitales. Il est écrit...^^~YOUH-OUH !~";
12: print "Le scarabée est devant vous, et fait des gestes bizarres avec ses pattes avant.";
13: print "Le scarabée est face à vous, et se dresse sur ses pattes avant, faisant si l'on peut dire le poirier.";
14: print "Le scarabée se remet à baver sur votre missel, plus vite cette fois.";
15: print "Le scarabée est en train d'écrire des lettres capitales, encore une fois ! Il est écrit :^^~T'ES MUET ?~";
16: print "Le scarabée est maintenant face à vous sur ses pattes arrière, et agite les pattes avant. Aucun doute, il a bien écrit ~T'ES MUET ?~ sur votre missel...Incroyable. Un signe divin, pensez-vous, le coeur battant.";}
print "^";
}
],
has animate concealed ;
Object cure "curé" eglise
with description "L'abbé Costicela, qui est en train de faire son sermon devant l'assemblée de fidèles. C'est le curé de votre ville, que vous connaissez depuis votre naissance - c'est lui qui vous a baptisé, rendez-vous compte, il y a longtemps déjà...",
name 'cure' 'abbe' 'pretre' 'sermonneur',
before [; Listen: "Le sermon du prêtre résonne dans l'église ; il parle d'injustice, de misère, et recommande de garder la foi malgré toutes les épreuves que le Ciel nous envoie. Vous approuvez son sermon, qui est assez inspiré aujourd'hui, avec force références bibliques...";
],
has animate concealed ;
Object fidele "fidèles" eglise
with description "Ce sont les fidèles, qui sont venus nombreux à la messe, comme chaque dimanche. Vous pouvez voir plusieurs visages connus - normal, vous allez à la messe régulièrement, et vous connaissez beaucoup de monde en ville...",
name 'fideles' 'chretiens' 'croyants',
has animate pluralname concealed ;
Object preteur "Chez le prêteur sur gages"
with description "La boutique du prêteur sur gages est une petite boutique, ancienne, où s'étalent divers objets hétéroclites, dont la plupart semblent avoir une certaine valeur... Mais vous n'êtes pas venu ici pour ça : vous êtes venu pour le sabre divin. Vous le remarquez rapidement : il est derrière le comptoir, accroché au mur, dans le dos du prêteur sur gages. Le vendeur vous regarde avec attention : c'est un petit bonhomme qui vous regarde par en-dessous, se forçant à sourire...",
out_to "Non, il vous faut le sabre !",
has ;
Object sabre "sabre" preteur
with description "C'est un superbe katana, un sabre japonais à lame courbe. Il a l'air normal, comme ça, mais, vous le savez, il est en réalité investi du pouvoir divin...",
name 'sabre' 'epee' 'katana' 'enchante' 'magique' 'sacre' 'divin',
before [; Take, Buy: defi(); rtrue;
],
has ;
Object objets "objets" preteur
with description "Ce sont les objets du prêteur sur gages. Il y en a beaucoup, et cela va de la montre plus ou moins ancienne aux bijoux plus ou moins brillants. Mais ce ne sont pas pour ces objets que vous êtes venu : vous êtes venu ici pour récupérer le sabre divin, que vous savez divin grâce au petit Djinn.",
name 'objets' 'heteroclites' 'divers' 'bijoux',
before [; Take: "Ces objets ne vous intéressent pas, n'allez donc pas dépenser votre argent en les achetant.";
],
has pluralname ;
Object pret "le prêteur sur gages" preteur
with description "C'est un petit bonhomme au regard fuyant, avec des petites moustaches, qui vous regarde et vous sourit d'un sourire quelque peu forcé. Un vendeur pas très avenant, donc...",
name 'preteur' 'gages' 'homme' 'fuyant',
before [; Ask, Tell: defi(); rtrue;
],
has animate proper ;
Object ring "La cave"
with description "Vous êtes dans un sous-sol poussiéreux et sombre, sur ce qui apparemment a été aménagé pour être une aire de combat. En temps normal, il doit y avoir d'autres combats - des combats clandestins, peut-être des combats de ~free fight~. Mais là, contraint et forcé, c'est vous combattez ! Vous ne savez pas ce que vous faites ici, à vrai dire ; mais désormais, vous êtes piégé dans ce sous-sol, avec ce mastodonte qui veut se battre avec vous, soufflant et sautillant, attendant que vous vous mettiez en position pour vous décrocher un autre uppercut, du même type que celui qui vous cuit encore la joue gauche... Vous n'aimez pas vous battre, et la violence n'est pas très christique, mais que pouvez-vous faire pour vous en tirer ?",
out_to "Vous pourriez, mais je ne crois pas que ~Babyface~ sera d'accord...",
has ;
Object joue "joue gauche" ring
with description "C'est la joue qui vient de recevoir un coup de poing : la douleur est cuisante, et votre joue doit être toute rouge." ,
name 'joue' 'gauche',
before [; Take: "C'est déjà votre joue.";
tendr: print "Vous rappelant des paroles du Christ, vous décidez de suivre son enseignement : après tout, si Dieu vous a envoyé une telle épreuve, c'est certainement pour voir votre réaction, et si vous cédez à la violence. Vous tendez alors la joue gauche, celle qui fut frappée, vers ~Babyface~. Celui-ci, surpris, vous regarde bizarrement, et se pose visiblement la question pendant quelques secondes de ce qu'il doit faire. Une telle stratégie le déroute certainement."; w8(); print "^^A la fin de sa réflexion, ~Babyface~ vous met un autre coup de poing. Jésus avait dit l'autre joue, pas la même joue gauche ! Ayant mal appliqué l'enseignement du Christ, et ayant même fait tout le contraire, il est normal que vous soyez puni. Le choc est rude : vous êtes à moitié sonné. Vous essayez de reprendre vos esprits, mais vous n'en avez pas le temps : ~Babyface~ continue à vous donner coup de poing sur coup de poing, et vous ne pouvez rien faire, sinon attendre que ça passe et encaisser. Et comme vous n'êtes pas non plus habitué à encaisser, vous tournez bien vite de l'oeil...^^Vous vous évanouissez sur le ring, sous les coups de votre adversaire."; w8(); print "^^Vous serez transporté à l'hôpital Saint-Luc, où vous décèderez des suites de vos blessures : ~Babyface~ y est allé trop fort, et vous n'étiez pas entraîné pour encaisser autant de coups. Les gens qui vous connaissaient en ville se demandent toujours pourquoi diable vous étiez dans un endroit aussi sordide et crapuleux, vous qui étiez toujours si propre sur vous et si fidèle à l'enseignement de Dieu.^^Mais malheureusement pour eux, ils n'ont pas le temps d'élucider ce mystère : sans prévenir, comme ça, un astéroïde percute violemment la Terre et la détruit, elle et son écosystème, et la raye de la carte de la voie Lactée..."; w8(); deadflag=1; rtrue;
],
daemon [k;
joug++;
switch(joug){
1: "^Votre joue gauche vous fait mal. Devant le boxeur, vous n'en menez pas large, et implorez mentalement l'aide du Seigneur...";
2: "^Peut-être qu'un miracle va arriver, et le Seigneur va vous tirer des griffes de ce lutteur musclé... Par pitié, faites qu'il arrive rapidement...";
3: "^Vous n'êtes pas habitué à vous battre. La dernière fois, ça devait être enfant, et vous aviez dû vous faire gronder. Vous êtes un chrétien placide, et vous n'êtes pas habitué à la violence... Vous voilà dans de beaux draps...";
4: "^Vous vous souvenez de la sainte parole divine : ne pas répondre à la violence par la violence, ne pas faire de mal, aimer ses ennemis. Mais alors, que pouvez-vous faire face à ce costaud qui menace de s'en prendre à votre autre joue, à votre visage, et vraisemblablement aussi au reste de votre corps ?";
5: "^Il y a quelque chose que vous ne comprenez pas. Vous qui êtes un envoyé de Dieu, pourquoi l'Eternel vous a-t-il envoyé ici, vous battre contre un boxeur, alors que Sa divine parole prône la non-violence ?";
6: "^Le Christ prônait certes la non-violence, mais alors, que pouvez-vous faire ? Non-violence, d'accord, mais que ferait le Christ face à un lutteur ?";
7: "^Comment faire ? Quelle est la parole divine à suivre dans ce cas ? Que ferait notre Seigneur face à ce mastodonte qui vous a déjà donné un coup de poing sur la joue gauche ?";
}
],
has concealed scenery female ;
Object joued "l'autre joue" ring
with description "C'est votre joue droite, celle qui est pour l'instant épargnée par les poings de ~Babyface~...",
name 'joue' 'droite' 'autre',
before [; Take: "C'est déjà votre joue.";
tendr: win(); rtrue;
],
has concealed scenery proper ;
Object boxeur "Babyface" ring
with description "~Babyface~ est un grand lutteur de deux mètres de haut ; il est grand, musclé, et a un bon jeu de jambes. Il est habitué à se battre, comme en témoigne sa tête bosselée, qui semble avoir reçu beaucoup de coups... Il vous a déjà mis un coup de poing, et menace d'en faire de même si vous n'êtes pas plus vigilant.",
name 'babyface' 'lutteur' 'boxeur' 'adversaire' 'opposant',
before [; Attack: print "Vous essayez de vous protéger et de bouger un peu vos jambes afin d'éviter les coups et de combattre ~Babyface~. A situation désespérée, remède désespéré... Et puis, vous suivez la loi du Talion, en décidant de rendre coup pour coup, oeil pour oeil, dent pour dent à ~Babyface~. Et si vous avez mauvaise conscience plus tard, il sera toujours temps de se confesser et d'expier le mal que vous allez faire à ~Babyface~..."; w8(); print "^^Péché d'orgueil ? Vous avez oublié un détal : vous n'êtes pas un lutteur professionnel...^^Sans prévenir, ~Babyface~ vous met un autre coup de poing. Le choc est rude : vous êtes à moitié sonné. Vous essayez de reprendre vos esprits, mais vous n'en avez pas le temps : ~Babyface~ continue à vous donner coup de poing sur coup de poing, et vous ne pouvez rien faire, sinon attendre que ça passe et encaisser. Et comme vous n'êtes pas non plus habitué à encaisser, vous tournez bien vite de l'oeil...^^Vous vous évanouissez sur le ring, sous les coups de votre adversaire."; w8(); print "^^Vous serez transporté à l'hôpital Saint-Luc, où vous décèderez des suites de vos blessures : ~Babyface~ y est allé trop fort, et vous n'étiez pas entraîné pour encaisser autant de coups. Les gens qui vous connaissaient en ville se demandent toujours pourquoi diable vous étiez dans un endroit aussi sordide et crapuleux, vous qui étiez toujours si propre sur vous et si fidèle à l'enseignement de Dieu.^^Mais malheureusement pour eux, ils n'ont pas le temps d'élucider ce mystère : sans prévenir, comme ça, un astéroïde percute violemment la Terre et la détruit, elle et son écosystème, et la raye de la carte de la voie Lactée..."; w8(); deadflag=1; rtrue;
],
each_turn [; tour++; if (tour==8) {print "Sans prévenir, ~Babyface~ vous met un autre coup de poing. Le choc est rude : vous êtes à moitié sonné. Vous essayez de reprendre vos esprits, mais vous n'en avez pas le temps : ~Babyface~ continue à vous donner coup de poing sur coup de poing, et vous ne pouvez rien faire, sinon attendre que ça passe et encaisser. Et comme vous n'êtes pas non plus habitué à encaisser, vous tournez bien vite de l'oeil...^^Vous vous évanouissez sur le ring, sous les coups de votre adversaire."; w8(); print "^^Vous serez transporté à l'hôpital Saint-Luc, où vous décèderez des suites de vos blessures : ~Babyface~ y est allé trop fort, et vous n'étiez pas entraîné pour encaisser autant de coups. Les gens qui vous connaissaient en ville se demandent toujours pourquoi diable vous étiez dans un endroit aussi sordide et crapuleux, vous qui étiez toujours si propre sur vous et si fidèle à l'enseignement de Dieu.^^Mais malheureusement pour eux, ils n'ont pas le temps d'élucider ce mystère : sans prévenir, comme ça, un astéroïde percute violemment la Terre et la détruit, elle et son écosystème, et la raye de la carte de la voie Lactée..."; w8(); deadflag=1; rtrue;}
],
daemon [k;
k = random(5); switch(k) {
1: "~Babyface~ est en face de vous, suant et transpirant, et il sautille. Il a un bon jeu de jambes.";
2: "~Babyface~ sautille, les poings à hauteur de sa tête, et souffle.";
3: "~Babyface~ fait une esquive tout en sautillant, pour vous montrer qu'il est prêt et réactif.";
4: "~Babyface~ feint de vous mettre un coup de poing ; il n'a pas voulu vous frapper, mais simplement tester vos réflexes. Ils sont bons : vous vous êtes reculés de plusieurs mètres en transpirant, et réprimant un cri.";
5: "~Babyface~ vous regarde en souriant. ~Viens là, avorton, bouge, un peu...~";
}
],
has animate concealed ;
!==========================================================
! Routines
[ Initialise;
give player light;
player.description = "Vous êtes un bon chrétien, chrétien jusqu'au bout des ongles. C'est à peu près tout ce que vous avez besoin de savoir dans ce jeu. D'ailleurs, mis à part votre dévotion à Dieu, vous êtes un personnage plutôt plat, qui semble être là uniquement pour faire avancer l'histoire...";
location = eglise;
lookmode=2;
StartDaemon(scarabee);
print_ret "C'est dimanche, un joli dimanche de juin, où le soleil filtre par les vitraux de l'église St François. Comme tous les dimanche matin, vous êtes à la messe, en bon chrétien. Vous écoutez, concentré, le sermon du prêtre, l'abbé Costicela, celui-là même qui vous a baptisé et pour qui vous étiez enfant de choeur... Dieu et vous, c'est une longue histoire, une histoire qui dure depuis plus de vingt ans, depuis votre naissance. Aujourd'hui, le sermon du prêtre est particulièrement inspiré, et parle d'injustices et de misère, et de foi, surtout. Vous n'êtes pas fâché d'être venu l'écouter - en même temps, il faut dire que vous n'avez pas raté beaucoup de messes dans votre vie...^^Soudain par la porte de l'église, un scarabée entre en voletant. Vous pouvez entendre son bourdonnement, la seule chose qui vient perturber le silence de l'église. Mais le scarabée ne ressort pas, vole dans l'église, se rapproche de vous, et finit même par atterrir sur votre pupitre ! Vous n'y prêtez guère attention, occupé que vous êtes à suivre le sermon du prêtre.^";
];
[ scaratalk ;
if (scarab<6){
print "Co... Comment avez-vous su ?? Comment avez-vous su qu'il fallait parler au scarabée ?! Il n'a encore rien fait ! Plusieurs hypothèses : soit vous êtes habitué à parler aux scarabées, et dans ce cas je ne peux rien pour vous, soit vous saviez que..."; w8(); print "^^Ah !! Je comprends tout, félon ! Vous êtes déjà mort et avez utilisé votre savoir acquis dans une de vos précédentes vies pour résoudre plus facilement l'énigme et avancer plus vite dans le jeu en ayant plus de points ! C'est évident ! Traître ! Vous n'êtes qu'un vil tricheur ! Et Dieu n'aime pas les tricheurs ! Judas ! Le châtiment divin sera terrible !"; w8(); deadflag=1;}
else {
score=score+16-scarab;
print "~Ah ben, pas trop tôt !~ s'exclame la voix du scarabée à l'intérieur de votre tête.";
if (scarab>12) {print " ~Il a quand même fallu que je fasse le poirier pour attirer ton attention, tu te rends compte ? Tu aurais pu m'éviter ça !~";}
w8();
print "^^Médusé, vous regardez autour de vous : personne d'autre que vous ne semble avoir entendu.^^Le scarabée reprend : ~Bon, tu m'écoutes, oui ? Je ne suis pas un scarabée. A l'heure actuelle je parle dans ta tête, c'est possible parce que tu as voulu me parler et donc tu as ouvert le canal de communication ! Je suis un djinn, et j'ai pris les traits d'un scarabée pour m'adresser à toi sans me faire repérer !^-Un djinn ?~ chuchotez-vous. ~Mais les djinns, c'est un truc de musulmans, c'est pas les chrétiens qui y croient !^-Hé, ho ! C'est jamais fini, avec vos religions ! Dieu, Allah, Bouddha, Goldorak, vous l'appelez comme vous voulez, c'est la même chose, c'est les instances suprêmes ! Bref, écoute-moi bien, toi : un astéroïde va percuter votre planète d'ici quelques heures, alors si tu ne te bouges pas vite fait, la Terre va y passer !"; w8(); print "^-Moi ? Mais pourquoi ?~ répondez-vous, très surpris. Puis vous réalisez : ~Oh, je suis un élu ! Un élu de Dieu ! Choisi par le Seigneur, c'est ça !^-Oui, oui, c'est ça, si tu veux, youpie, félicitations !... Ecoute-moi, un peu ! Afin d'éviter ce cataclysme - tu ne voudrais pas finir comme ça, hein ? - on a donné un pouvoir divin à un objet commun, pour que tu puisses t'en servir pour sauver le monde !~^Sauver le monde, comme il y va... Voilà qu'il vous met la pression..."; w8(); print "^Le scarabée reprend :^~Il s'agit d'une épée, un katana magique, investi de pouvoirs suprêmes ; il te servira pour détourner l'astéroïde, d'accord ?^-Moi ? Mais... Où se trouve-t-il ?^-26, rue de la République.~ vous répond-t-il du tac au tac. Puis, devant votre air ahuri, il ajoute : ~Quoi, tu croyais que ça allait être dans la forêt de Brocéliande ? Qu'on allait te faire crapahuter partout et accomplir des quêtes ridicules, du genre sauver un canard, pour finalement creuser avec tes doigts pour trouver le katana ? Eh non, mon vieux ! Le meilleur moyen de planquer une relique, c'est au milieu d'autres objets normaux, tu comprends ? Donc tu y vas, tu prends l'épée, et tu détournes l'astéroïde, c'est pas compliqué, non ?~"; w8(); print "^Mais mal à l'aise, vous ne pouvez vous empêcher de demander : ~-Mais... Pardon, mon Dieu, mais pourquoi moi, un simple humain ?^-Pourquoi pas Dieu, c'est ça ? ^-Eh bien... Oui... Il me semble qu'il serait plus à même de...^-Réfléchis, neuneu ! L'astéroïde, tu crois qu'il est là par hasard ? Qu'il a suivi une route aléatoire et que Dieu l'a pas vu au dernier moment ? Bien sûr que non ! C'est Dieu qui l'envoie sur Terre pour vous faire peur et vous inciter à garder la foi !... Enfin presque..."; w8(); print "^~- Presque ?^-Ben... Ca c'est ce qu'il dit... Mais la version officieuse... Ne le répète à personne... Il se chuchote qu'il était en réalité en train de jouer au bowling, et qu'il avait un peu trop forcé sur l'ambroisie... Tu vois ce que je veux dire ?~^Horrifié, vous écarquillez les yeux. Le scarabée reprend : ~Oh, ça va, fait pas cette tête-là... Ca arrive, des accidents comme ça, et il a pas voulu perdre la face, c'est tout... Encore heureux qu'il vous ait donné les moyens de vous défendre ! Bon... En clair, t'as compris, t'as pas le choix, tu dois sauver ta planète, d'accord ?^-Oui chef !~ faites-vous automatiquement.";
w8();
print "^^Le scarabée vous adresse un salut militaire, puis disparaît comme par miracle. Il vous a donc investi d'une mission divine : à vous de vous montrer digne du poids qui pèse sur vos épaules !";
}
StopDaemon(scarabee);
];
[ defi ;
print "Vous saluez le prêteur sur gages et lui dites que vous souhaitez acquérir le katana.^^~Vous voulez le sabre ?~ Il sourit d'un air qui ne dit rien de bon... ~Ah ah... Pour une collection ?^-Non... Raisons personnelles...^-Ah, bien sûr, je vois... C'est un beau sabre, n'est-ce pas ? Il coûte cher... Mais j'imagine que vous le voulez vraiment, n'est-ce pas ?^-Oui !^-Tant que ça ? Vous seriez prêt à vous battre pour l'avoir ?^-Oui, il me le faut !~ répondez-vous."; w8(); print "^Le visage du prêteur s'illumine. Très intéressé, il vous prend par le bras. ~Allons-y~ dit-il.^^Allons-y ?? Où ça ? Où vous emmène-t-il ? Le prêteur vous prend par le bras et vous emmène dans l'arrière-boutique. Vous descendez de petits escaliers, et vous vous retrouvez au sous-sol."; w8(); print "^^Vous finissez par arriver dans une sorte de salle poussiéreuse, une sorte de sall d'entraînement pour boxeurs aménagée dans le sous-sol du bâtiment, si vous en croyez les punching-balls et les gants qui sont là. Et surtout vous voyez un grand musclé, qui saute à la corde en transpirant.^^~Babyface !^-Oui ?~ La masse de muscles approche.^~Voilà ton adversaire du jour !~"; w8(); print "^^Oh oh... Quoi ? Mais... Vous n'avez... Pourquoi voudriez-vous...^^Quand le prêteur disait ~se battre pour le sabre~, lui l'entendait au sens propre... Mais jamais de la vie, vous refusez de combattre ce... ~Babyface~ !^^~Vous allez combattre, sur le ring, vous deux, et sans gants ! Si vous gagnez le combat, vous pourrez prendre le sabre, que je mets ici, au pied du ring. Sinon... Tant pis pour vous ! Bonne chance !~^^Qu'est-ce que c'est que cette histoire de fous ? Mon Dieu, à l'aide !^^Vous n'avez pas le temps de réagir que ~Babyface~ est sur vous. Il vous prend par l'épaule et vous fait monter sur le ring. Vous hurlez, vous vous débattez, mais c'est peine perdue : il est trop fort pour vous."; w8(); print "^^Vous êtes soudain debout sur le ring, et ~Babyface~ vous fait face : il sautille en souriant d'un air mauvais. Il s'est déjà échauffé, et s'apprête à vous croquer tout cru...^^Soudain, alors que vous ne vous y attendiez pas, il vous décoche un coup de poing sur la joue gauche. Ca fait très mal. Vous vous êtes laissé surprendre ; vous vous reculez, vous frottez la joue, reprenez vos esprits, et essayez de trouver un moyen de vous en sortir. Votre joue gauche vous fait mal. Ca va mal pour vous, vous vous êtes laissé embarquer dans une drôle de galère... Seul un miracle...^^";
PlayerTo(ring);
StartDaemon(joue);
StartDaemon(boxeur);
rtrue;
];
[ win ;
score=score+8-joug;
print "Décidant de faire preuve de foi et de vous comporter en bon chrétien, vous appliquez l'enseignement du Christ : vous tendez la joue droite, puisque ~Babyface~ vous a frappé sur la joue gauche. Matthieu, 5:39.^^Ce geste déconcerte votre adversaire : lui qui se préparait à frapper s'arrête, décontenancé. Il hésite. Vous pouvez deviner les rouages de son cerveau qui s'affolent.";
w8();
print "^^Puis finalement, sans prévenir, il fond en larmes. C'est touchant. Vous vous approchez de lui, doucement, en vous assurant qu'il ne vous fera rien, et le prenez dans vos bras. Le lutteur sanglote :^^~Oh, pardonne-moi... J'avais oublié... Comment avais-je pu oublier... Tu viens de me faire réaliser que... Nous sommes tous frères... Et... Je ne dois pas te faire de mal ! La violence n'est pas bonne ! Je dois... Je dois aimer mon prochain, au lieu de le haïr... Je dois aimer mes ennemis ! Bouh, je suis désolé... Comment ai-je pu oublier mon catéchisme... Je me rends compte que... Je croyais que Dieu était avec moi, je le priais, mais j'étais si loin de la lumière... Merci de m'avoir montré la voie, de m'avoir ramené à la lumière... Tu es mon sauveur personnel... Tu es mon berger, j'étais un mouton égaré, et tu m'as montré la voie, tu m'as ramené dans le bon troupeau... Merci...~^^Et la grande montagne de muscles vous embrasse et vous serre, tout en vous remerciant. Vous vous sentez bien : vous avez sauvé quelqu'un de lui-même et de ses péchés...^^Vous souriez, et vous vous rappelez de pourquoi êtes-vous venus. Vous donnez une tape amicale sur l'épaule du lutteur, lui pardonnez ses erreurs, et finalement, descendez du ring pour prendre l'épée et accomplir la volonté de Dieu.";
w8();
print "^^Quelques heures plus tard, alors que vous attendiez sur un banc, l'épée à la main, vous voyez enfin l'astéroïde dans le ciel : il se rapproche de plus en plus de la Terre. Les gens qui passent lèvent la tête, et commencent à prendre peur : bientôt, c'est la panique. Le katana commence à briller d'un éclat surnaturel, divin, et vous sentez une grande force dans cette épée. Vous le pointez en direction de l'astéroïde et vous concentrez, en priant mentalement ~Seigneur, que ta volonté soit faite !~.^^Un éclair de lumière part du katana en direction de l'astéroïde ; surpris, vous n'en gardez pas moins votre concentration. Vous voyez l'astéroïde qui soudain s'arrête de grossir dans le ciel ; l'éclair semble le retenir... Et d'un coup, vous le voyez s'éloigner et prendre la direction du soleil à une vitesse incroyable, où il finira sans doute carbonisé.";
w8();
print "^^Heureux, vous vous sentez dans un état de totale béatitude. Vous avez réussi la mission divine qui vous était confiée ! Vous avez sauvé le monde !^^Mais, modeste, vous esquissez un sourire et vous éloignez avec le katana. Vous vous sentez renouvelé, dans vous, dans votre foi, comme si vous aviez mué et vous étiez débarrassé d'une vieille enveloppe corporelle. Vous prenez conscience que la vie est longue, et que vous avez du travail, que vous vous devez de sauver les égarés et les pécheurs. Le Ciel attendra que en vous ayez fini avec les humains.";
w8();
deadflag=2;
];
[ chassSub ;
"Vous ne pouvez chasser ceci.";
];
[ tendrSub ;
"Vous ne pouvez tendre ceci.";
];
[ lirSub ;
<Examine noun>;
];
[ prieSub ;
if (pri==0) {score=score+3; pri++;}
print_ret "Vous fermez les yeux, vous concentrez, joignez vos mains devant vous et commencez à prier en silence. Après quelques minutes, vous ouvrez vos yeux : vous sentez la paix intérieure vous gagner et vous reprenez espoir...";
];
[ aideSub ;
style bold;
print "^Châtiment divin";
style roman;
print_ret "^^Un jeu de Hugo Labrande.^^Créé à l'occasion des deuxièmes Rapid-Fictions du 26 août 2007.^^Les thèmes étaient les suivants (il fallait en choisir 3, mais tous sont présents dans ce jeu : orgue, katana, scarabée, lutte, astéroïde, djinn.^^Une bonne connaissance de la Bible n'est pas requise pour jouer à ce jeu ; cependant, ce jeu présente la première énigme chrétienne jamais créée. Pour la résoudre, un peu de culture générale suffit, ou bien l'Evangile de Saint Matthieu (mettez votre réveil à 5 heures 39 du matin précises, ainsi vous trouverez la solution plus facilement).^^Pour des remarques, commentaires ou signalement de bugs, écrivez moi à l'adresse mulehollandaise_at_msn.com";
];
!==========================================================
! Grammaire
Include "FrenchG";
Verb 'chasser'
* noun -> chass;
Verb 'tendre'
* noun -> tendr;
Extend 'lire' replace
* noun -> lir;
Extend 'prier' replace
* -> prie;
Verb 'aide'
* -> aide;