!==========================================================
Constant Story "Divine bonace";
Constant Headline
 	"^Un jeu par Théoclès Philocratos^Participant à la French MiniComp 2007^Tapez ~aide~ pour l'aide du jeu^";
Release 1; Serial "070711";

Include "Parser";
Include "VerbLib";

[ w8 notNeeded;
  @read_char 1 notNeeded;
  rtrue;
];

!==========================================================
! Objets et lieux

!==========================================================
! En haut du bateau

Object pont1 "Pont supérieur"
	with description "Le pont supérieur est éclairé par un grand soleil en cette matinée. La mer est calme, et le bateau ne semble pas bouger beaucoup. Quelques marins oisifs jouent aux dés ici ; l'un d'eux est adossé au mât où pend la grande voile.^^Le pont supérieur continue devant vous, vers le nord, mais vous pouvez toujours descendre par l'écoutille derrière vous.",
	n_to pont2,
	in_to ecout1,
	d_to ecout1,
has scenery concealed ;

Object mat "grand mat" pont1
	with description "La grande voile pend lamentablement au mât, en l'absence totale de vent.",
	name 'grand' 'grande' 'voile' 'mat',
	before [; Take, Push, Pull: "Ne présumez pas de vos forces.";
	],
has scenery concealed ;

Object mer "mer"
	with description [; if (rev.told==1) {"Vous regardez intensément la mer, et vous voyez un nouvel éclat lumineux : pas de doute, il y a bien quelque chose qui brille au fond de l'eau.";} else {"La mer est calme, et il n'y a pas trop de remous. Le bateau quant à lui n'avance pas, victime d'une absence totale de vent.";}
			],
	name 'mer' 'ocean' 'vagues' 'mediterranee',
	found_in pont1 pont2,
	before [; Take, Push, Pull : "Drôle d'idée.";
		Smell: "L'air marin sent bon le sel et les embruns.";
		Listen: "La mer est calme, et on entend seulement les clapotis de l'eau.";
	],
has female scenery concealed ;


Object cordages "cordages" pont1
	with description "Ce sont des gros cordages, enroulés.",
	name 'corde' 'cordes' 'cordage' 'cordages',
	before [; Take : "Ils sont trop lourds.";
		deroul: "Ca ne vous servirait à rien.";
		Search : if (marins.told>2) {if (fil notin player) {move fil to pont1; "Parmi les cordages, vous voyez ce qui semble être un fil de pêche.";} else {"Vous regardez parmi les cordages, mais vous ne voyez rien de particulier.";}
						}
			else {
				if (marins.told==1) {marins.told=2; move cout to pont1; "Vous fouillez parmi les cordages enroulés, et vous finissez par y voir un couteau de cuisine.";}
				else {"Vous regardez parmi les cordages, mais vous ne voyez rien de particulier.";}
			}
	],
has pluralname static ;

Object cout "couteau de cuisine"
	with description "C'est un grand couteau de cuisine, aiguisé et coupant, et avec un large manche. Attention quand vous le manipulez.",
	name 'couteau' 'cuisine',
has concealed ;


Object pont2 "Pont supérieur"
	with description "Devant vous, sur cette partie du pont supérieur, un marin est penché nonchalamment sur le bord du bateau et regarde la mer.^^Le pont supérieur continue au sud. Vous pouvez descendre vers l'intérieur du bateau par l'écoutille devant vous.",
	s_to pont1,
	in_to ecout2,
	d_to ecout2,
has scenery concealed ;

Object coupe "coupe en bronze"
	with description "C'est une coupe en bronze, lourde et de couleur sombre, qui semble de surcroît avoir une certaine valeur.",
	name 'coupe' 'bronze' 'marron' 'lourde' 'boisson' 'breuvage',
	before [; LetGo: "Vous ne pouvez pas, les ingrédients sont mélangés à l'intérieur de la coupe...";
		Drink: if (miel in coupe && levure in coupe && eau in coupe && vin in coupe) {vision(); rtrue;} else {"Vous n'avez pas encore recueilli tous les ingrédients.";}
		Smell: if (miel in coupe || levure in coupe || eau in coupe || vin in coupe) {"Le breuvage du devin sent bon, une odeur sucrée et douce.";} else {"La coupe est vide.";}
		],
has female container transparent ;

Object poisson "poisson"
	with description "C'est le poisson que vous venez juste de pêcher ; il est sur le pont du bateau, encore un peu frétillant.",
	name 'poisson' 'frai' 'frais' 'fretillant',
	before [; Open, Search: fin(); rtrue;
		Smell: "Bien sûr, ce poisson sent... le poisson.";
		],
has ;

!==========================================================
! Au milieu du bateau

Object ecout1 "Une écoutille"
	with description "A côté de vous, il y a un tas de choses diverses : outils, cordes... Devant vous, au nord, vous pouvez aller dans un couloir. Vers le nord-ouest, vous pouvez entrer dans la cuisine ; mais vous pouvez aussi sortir sur le pont supérieur du bateau.",
	u_to pont1,
	out_to pont1,
	n_to couloir,
	nw_to cuisine,
has scenery concealed ;

Object tas "tas" ecout1
	with description "C'est un amas de choses comme par exemple un balai, des cordes, et un grand et long bâton...",
	name 'tas' 'amas' 'choses' 'outils',
	before [; Take: "Ces choses sont trop volumineuses, et inutiles.";
		Search: "Rien de bien intéressant, mis à part ces cordes, le balai et le grand bâton.";
		],
has scenery concealed ;

Object balai "balai" ecout1
	with description "C'est le balai qui sert pour le ménage dans le bateau.",
	name 'balai',
	before [; Take: "Ca ne vous servirait à rien.";
		],
has scenery concealed ;

Object cordes "cordes" ecout1
	with description "Ce sont des cordes, entrelacées. On a souvent besoin de cordes sur un bateau.",
	name 'corde' 'cordes' 'cordage' 'cordages',
	before [; Take: "Ca ne vous servirait à rien.";
		],
has pluralname scenery concealed ;

Object baton "baton" ecout1
	with description "Il s'agit d'un bâton ; long et grand, il a l'air robuste...",
	name 'baton' 'long',
	before [; Take: if (marins.told<3) {"Ca ne vous servirait à rien.";}
			else {
				if (canne notin player) {remove baton; move canne to player; "Ce bâton serait parfait pour faire une canne à pêche, pensez-vous en le prenant...";}
				else {"Ca ne vous servirait à rien.";}
			}
		],
has scenery concealed ;

Object ecout2 "Une écoutille"
	with description "Il n'y a pas grand'chose ici, si ce n'est l'écoutille au sol, qui permet de descendre à la cale. Sinon, vous pouvez ressortir sur le pont supérieur, ou aller vers le sud, vers le couloir.",
	u_to pont2,
	out_to pont2,
	d_to cale1,
	s_to couloir,
has scenery concealed ;

Object couloir "Dans le couloir"
	with description "Ce couloir fait communiquer les deux écoutilles aux extrémités du bateau, et les quelques pièces nécessaires à l'équipage.^^Vous pouvez aller au nord ou au sud, vers les écoutilles, ou bien à l'ouest, vers la cuisine ; à l'est, ce sont les quartiers de l'équipage.",
	n_to ecout2,
	s_to ecout1,
	w_to cuisine,
	e_to quart,
has scenery concealed ;

Object cuisine "La cuisine"
	with description "Ici, c'est la cuisine, et ça se sent ; de la nourriture est stockée un peu partout, et les étagères regorgent de victuailles en tous genres. Le cuisinier est sur la table, en train d'éplucher des légumes.^^Vous pouvez revenir vers l'est, vers le couloir, ou au sud-ouest vers l'écoutille.",
	before [; Smell: "La cuisine est pleine de senteurs : les herbes, les légumes, les odeurs sucrées, salées, tout cela vous emplit fortement les narines...";
		],
	e_to couloir,
	se_to ecout1,
has scenery concealed ;

Object etagere "victuailles" cuisine
	with description "Les étagères regorgent de victuailles, fruits, légumes... Mais votre cuisinier vous défendrait d'y toucher, il n'apprécierait pas que vous veniez chaparder dans ses réserves...",
	name 'etageres' 'etagere' 'fruits' 'fruit' 'légumes' 'légume' 'reserves' 'reserve' 'victuaille' 'victuailles' 'nourriture',
	before [; Take: "Le cuisinier vous arrête dans votre élan : ~Hé, oh, qu'est-ce que comptes faire, là ?~";
		],
has pluralname scenery concealed ;

Object tablecuis "table" cuisine
	with description "C'est la table qui sert au cuisinier pour préparer ses plats.",
	name 'table',
has scenery concealed ;

Object quart "Quartiers de l'équipage"
	with description "Vous êtes à proximité des quartiers de l'équipage ; quelques tables, et quelques chaises, qui servent en général pour manger le soir, ou alors simplement pour s'installer avec vos camarades. A l'heure actuelle, il n'y a personne, sauf Catirias, le devin, assis seul à une table, en train de rêver à Zeus sait quoi.^^Devant vous, au nord, vous pouvez aller dans le dortoir. Au sud, c'est la cabine du capitaine. Vous pouvez rejoindre le couloir à l'ouest.",
	w_to couloir,
	n_to dortoir,
	s_to [; if (devin.told<2) {"La porte est fermée.";} else {return chambrcap;}
		],
has scenery concealed ;

Object tables "tables" quart
	with description "Il y a quelques tables ici ; ce sont les tables qui vous servent d'habitude, à vous et à vos camarades, pour manger ou jouer aux cartes. Il y en a relativement peu, mais il faut dire que l'équipage n'est pas très nombreux à bord de ce bateau.^Le devin Catirias est assis à l'une de ces tables, seul.",
	name 'table' 'tables',
has pluralname scenery concealed ;

Object chaises "chaises" quart
	with description "Quelques chaises et tabourets en bois, à proximité des tables.",
	name 'chaises' 'chaise' 'tabouret' 'tabourets',
has pluralname scenery concealed ;

Object portcap "porte" quart
	with description "C'est la porte de la cabine du capitaine.",
	name 'porte' 'cabine' 'capitaine',
	before [; Open: if (devin.told<2) {"La porte est fermée.";} else {PlayerTo(chambrcap); rtrue;}
		],
	door_to chambrcap,
	door_dir s_to,
has female scenery concealed door openable ;

Object dortoir "Le dortoir"
	with description "C'est le dortoir où l'équipage dort : des hamacs sont tendus entre deux poutres de la coque du bateau, et des lits de camps sont au sol. Il y a quelques affaires dans la pièce, un peu partout.^^Vous pouvez revenir au sud vers les quartiers de l'équipage.",
	s_to quart,
has scenery concealed ;

Object affaires "affaires" dortoir
	with description "Quelques choses diverses, éparpillées dans la pièce.",
	name 'affaires' 'choses' 'bazar',
	before [; Take: "Vous n'allez pas tout prendre, c'est trop volumineux, et en plus elles ne sont pas à vous.";
		Push, Pull: "Les affaires sont un peu partout dans la pièce : mieux vaut ne pas y toucher...";
		Search: if (hamecon.taken==0) {move hamecon to dortoir; "Vous trouvez ce qui semble être appartenir à un pêcheur : un hameçon, avec un appât au bout.";} else {"Vous ne trouvez rien de bien intéressant.";}
	],
has scenery concealed ;

Object mockpiece "dortoir" dortoir
	with description "C'est le dortoir où l'équipage dort : des hamacs sont tendus entre deux poutres de la coque du bateau, et des lits de camps sont au sol. Il y a quelques affaires dans la pièce, un peu partout.^^Vous pouvez revenir au sud vers les quartiers de l'équipage.",
	name 'piece' 'dortoir',
	before [; Search: if (hamecon.taken==0) {move hamecon to dortoir; "Vous trouvez ce qui semble être appartenir à un pêcheur : un hameçon, avec un appât au bout.";} else {"Vous ne trouvez rien de bien intéressant.";}
		],
has scenery concealed ;

Object lits "lits de camp" dortoir
	with description "Des lits de camp, rudimentaires, sont au sol. C'est mieux que rien pour dormir, tout de même.",
	name 'lits' 'lit' 'camp',
	before [; Take: "Ca ne vous servirait à rien.";
		],
has pluralname scenery concealed ;

Object hamac "hamacs" dortoir
	with description "Ce sont des hamacs, tendus entre deux poutres de la coque du bateau. A vrai dire, vous préférez dormir dans un hamac plutôt que par terre, mais vous n'êtes apparemment pas le seul et parfois, vous êtes forcé de dormir par terre...",
	name 'hamacs' 'hamac',
	before [; Take: "Ca ne vous servirait à rien.";
		],
has pluralname scenery concealed ;

Object chambrcap "La cabine du capitaine"
	with description "La cabine du capitaine est assez grande et lumineuse. De beaux meubles et un lit individuel montrent bien que le capitaine a droit à certains égards dûs à son rang... Il est d'ailleurs là, assis sur une chaise, en train d'étudier les cartes de navigation en grommelant.^^Vous pouvez sortir par le nord, vers les quartiers du reste de l'équipage.",
	n_to quart,
	out_to quart,
has scenery concealed ;

Object cartes "cartes" chambrcap
	with description "Vous regardez les cartes de navigation : c'est la Méditerranée, et le capitaine a tracé votre trajet depuis le début. Mais là, apparemment, il est en train d'étudier ses cartes pour voir quelle route vous permettrait de profiter de vents favorables...",
	name 'carte' 'cartes' 'navigation',
	before [; Take, Push, Pull: "Le capitaine est en train de les étudier.";
		],
has pluralname scenery concealed ;

Object lit "lit" chambrcap
	with description "Le lit individuel du capitaine, impeccablement fait. Il a l'air confortable, en tout cas plus que vos lits de camp dans le dortoir... Mais bon, un des avantages à être capitaine...",
	name 'lit',
has scenery concealed ;

Object meubles "meubles" chambrcap
	with description "Ce sont des meubles : une étagère, une petite table... Ils sont beaux ; en fait, ils ont l'air d'avoir été lustrés - le capitaine a dû s'ennuyer...",
	name 'etagere' 'table' 'meubles' 'meuble',
has pluralname scenery concealed ;

Object canne "canne à pêche"
	with description "C'est une canne à pêche, rudimentaire, certes, mais l'important c'est que vous puissiez pêcher avec.",
	name 'canne' 'peche',
has concealed ;

Object fil "fil de peche"
	with article "du",
	description "Du fil de pêche, qui semble assez résistant.",
	name 'fil' 'peche',
has concealed ;

Object hamecon "hameçon"
	with taken 0,
	description "Ce hameçon est coupant, et il a dû servir il y a peu : il y a encore un appât dessus.",
	name 'hameçon' 'crochet' 'appat',
	before [; Take: self.taken=1;
		],
has concealed ;

!==========================================================
! Au fond du bateau

Object cale1 "Dans la cale"
	with description "Vous vous trouvez dans la cale du bateau. Ici, dans les profondeurs du bateau, on le sent tanguer et grincer plus fort que sur le pont... Dans la cale sont entreposées les vivres pour votre voyage ; vous voyez aussi des amphores, remplies d'eau douce.^^Vous pouvez remonter par l'écoutille au-dessus de vous. Devant vous, vers le sud, la cale continue dans la pénombre.",
	before [; Listen : "Pas grand'chose, à part le grincement du bateau et le clapotis de la mer.";
		],
	u_to ecout2,
	s_to cale2,
has scenery concealed ;

Object ampheau "amphores" cale1
	with description "Ce sont de grosses amphores en terre, remplies d'eau douce.",
	name 'amphore' 'amphores' 'recipient' 'recipient' 'jarre' 'jarres' 'pot' 'pots',
	before [; Take, Push, Pull : "Les amphores sont trop lourdes pour vous.";
		Open : <Open b1>; rtrue;
		Close : <Close b1>; rtrue;
		Search: "Vous cherchez entre les amphores, mais vous ne trouvez rien.";
		],
has pluralname scenery concealed ;

Class bouchon
	with parser_name 'couvercle',
	name 'couvercle' 'bouchon',
	before [; Take : if (self hasnt open) {give self open; "Vous poussez le couvercle, ouvrant plus largement l'amphore.";} else {"Le couvercle de l'amphore est déjà poussé et l'amphore est entrouverte.";}
		Push, Pull : if (self has open) {give self ~open; "Vous poussez le couvercle de l'amphore afin de la boucher un peu ; mais même ainsi on voit qu'elle a été ouverte.";} else {give self open; "Vous poussez le couvercle, ouvrant plus largement l'amphore.";}
		Open : if (self hasnt open) {give self open; "Vous poussez le couvercle, ouvrant plus largement l'amphore.";} else {"Le couvercle de l'amphore est déjà poussé et l'amphore est entrouverte.";}
		Close : if (self has open) {give self ~open; "Vous poussez le couvercle de l'amphore afin de la boucher un peu ; mais même ainsi on voit qu'elle a été ouverte.";} else {"L'amphore est déjà bouchée, du moins en partie...";}
		],
has openable ~open scenery concealed ;

Bouchon b1 cale1
	with description [; if (self hasnt open) {"L'amphore est un peu entrouverte - normal, c'est ici que l'équipage puise ses réserves d'eau douce pour le voyage...";} else {"L'amphore est ouverte, et elle semble à moitié remplie.";}],
	each_turn [; if (self hasnt open) {remove eau1;} else {move eau1 to cale1;}];

Object cale2 "Dans la cale"
	with description "Vous arrivez au bout de la cale. Autour de vous, des amphores dégagent une odeur de raisin fermenté et de bon vin. L'une d'elles a l'air entrouverte, peut-être par le cuisinier, ou par un membre d'équipage, un marin qui aurait eu soif ou envie de se saoûler...^^Vous pouvez repartir au nord vers le devant de la cale.",
	before [; Smell : "Vous sentez une odeur d'alcool, une odeur agréable qui n'est pas non plus très forte - pas de quoi finir ivre, mais ça donne envie d'y respirer à côté...";
		Listen : "Pas grand'chose, à part le grincement du bateau et le clapotis de la mer.";
		],
	n_to cale1,
has scenery concealed ;

Object amphvin "amphores" cale2
	with description "Ce sont des amphores normales, en terre cuite. Elles sont remplies du vin que vous devez amener à Athènes. L'une d'elles a son couvercle un peu soulevé : quelqu'un a dû l'ouvrir...",
	name 'amphore' 'amphores' 'ouverte' 'recipient' 'recipient' 'jarre' 'jarres' 'pot' 'pots',
	before [; Take, Push, Pull : "Les amphores sont trop lourdes pour vous.";
		Open : <Open b2>; rtrue;
		Close : <Close b2>; rtrue;
		Search: if (cuisinier.told<2) {move louche to cale2; "Vous finissez par voir, coincée entre deux amphores, une louche en bois. Tiens tiens... Vous saviez bien que quelqu'un était passé par là...";} else {"Vous cherchez, mais vous ne trouvez  rien.";}
		Smell : "Vous sentez une odeur d'alcool, une odeur agréable qui n'est pas non plus très forte - pas de quoi finir ivre, mais ça donne envie d'y respirer à côté...";
		],
has pluralname scenery concealed container ;

Bouchon b2 cale2
	with description [; if (self hasnt open) {"Le couvercle de cette amphore a visiblement été soulevé - quelqu'un est déjà passé par là...";} else {"L'amphore est ouverte, et vous pouvez voir qu'elle est remplie quasiment jusqu'au bord.";} ],
	each_turn [; if (self hasnt open) {remove vin1;} else {move vin1 to cale2;}];

Object louche "louche"
	with description "C'est une grande louche en bois. Elle sent légèrement le vin ; ça et le fait qu'elle se trouve ici laisse à penser qu'un des marins l'a utilisée pour se servir en vin...",
	name 'louche' 'bois' 'creuse',
has concealed ;

!==========================================================
! Ingrédients

Class ingredient
	with description [; print_ret (The) noun, " est dans la coupe, mélangé aux autres ingrédients.";
		],
has scenery;

Ingredient miel "miel"
	with article "du",
	name 'miel',
	before [; Drop: "Vous n'avez pas vraiment envie de renverser la coupe.";
	];

Ingredient levure "levure"
	with article "de la",
	name 'levure',
	before [; Drop: "Vous n'avez pas vraiment envie de renverser la coupe.";
		];

Object eau1 "eau douce"
	with description "Ce sont les réserves en eau douce de l'équipage pour le voyage.",
	name 'eau' 'douce',
	before [; Take: if (coupe in player) {move eau to coupe; "Vous prenez un peu d'eau dans les réserves d'eau douce, et la placez dans la coupe de bronze.";} else {"Vous n'avez rien pour transporter l'eau.";}
		],
has scenery concealed ;

Ingredient eau "eau douce"
	with article "de l'",
	name 'eau' 'douce',
	before [; Drop: "Vous n'avez pas vraiment envie de renverser la coupe.";
		];

Object vin1 "vin"
	with description "C'est le vin que vous deviez amener à Athènes à l'occasion des Panathénées.",
	name 'vin' 'alcool' 'pinard',
	before [; Take: if (coupe in player) {move vin to coupe; "Vous prenez un peu de vin et le placez dans la coupe de bronze. Espérons que les dieux ne vous en voudront pas, mais c'est pour la bonne cause, après tout.";} else {"Vous n'avez rien pour transporter le vin.";}
		],
has scenery concealed ;

Ingredient vin "vin"
	with article "du",
	name 'vin' 'alcool' 'pinard',
	before [; Drop: "Vous n'avez pas vraiment envie de renverser la coupe.";
		];

Object raisin "raisin" cuisine
	with taken 0,
	article "du",
	description "C'est une grappe de raisin, des raisins violets et juteux à souhait.",
	name 'grappe' 'raisin' 'grains',
	before [; Squeeze: if (coupe in player) {remove raisin; move vin to coupe; "Vous pressez soigneusement le raisin et recueillez le jus dans la coupe. Ca n'est pas exactement le vin que vous avait demandé le devin, mais enfin, on ne va pas non plus lui donner un grand cru !";} else {"Vous n'avez pas de récipient pour recueillir le jus.";}
		Take: if (self.taken==0) {self.taken=1; move raisin to player; "~Une petite faim, mon gars ? Bah, prends-la, j'en ai encore plein !~^^En remerciant le cuisinier, vous prenez la grappe de raisin.";}
		Eat: "Vous n'avez pas tellement faim.";
		],
has ;


!==========================================================
! Personnages

Object marins "marins" pont1
	with told 0,
	description "Ils sont quelques marins à jouer aux dés et à profiter du soleil sur le pont supérieur.",
	name 'marins' 'marin' 'matelots' 'matelot' 'hommes' 'homme' 'equipage' 'joueurs' 'joueur',
	before [; Tell, Ask: switch(self.told){
		0: "Vous échangez quelques paroles sur la situation avec les marins ; ils sont assez détendus en surface, mais semblent quand même préoccupés par la situation. ~A croire que les dieux sont contre nous.~, lâche l'un d'entre eux.";
		1: "Vous vous approchez du groupe de marins et leur dites que le cuisinier cherche ses ustensiles. Un des marins occupés à jouer aux dés lève la tête :^^~Ah ! Oui, c'est moi ! Ben, il peut les récupérer, mais le problème c'est que... Je sais pas bien où est-ce que je les ai mis... Bah, ils doivent être quelque part par là, tout de même...~^^Et, l'air de prendre ça très au sérieux, il retourne à son jeu.";
		2: if (louche in player) {"Vous revenez voir le marin et lui dites que vous avez retrouvé la louche près des amphores à vin... Le visage empourpré, celui-ci répond :^^~Ah bon ? Vous êtes sûr ? Mince, alors, parce que je n'y suis pas allé, moi, à la cale... Si, si, je vous assure... Bah, ça doit... C'est sûrement un rat, pas vrai ?~^^Mouais... Un concentré de mauvaise foi, mais après tout, c'est son affaire, et vous n'avez pas envie ni de le dénoncer ni de le faire chanter, alors...";} else {"Vous revenez voir le marin en lui disant que vous avez retrouvé le couteau, mais pas la louche. Il vous regarde, et d'un coup semble un peu gêné...^^~Ah tiens, c'est bizarre, pourtant je devais les avoir mis ensemble... Je sais pas du tout où la louche a bien pu passer, mais alors pas du tout... Elle doit pas être bien loin, de toute façon...~^Un des marins l'interpelle : ~Eh, t'es sûr que tu t'en es pas servi pour picoler un peu ?~^L'autre devient rouge :~Euh, non, non, pas du tout ! Enfin, non, euh, bien sûr que non...~";}
		3: "Vous saluez les marins et leur racontez ce que le devin vous a dit. L'un d'eux fait la moue : ~Mouais. Moi, j'y crois pas trop, à ce que dit le devin...^-En attendant, c'est possible ! fait un autre.^-Ouais, qu'est-ce que tu veux faire, pour se dépêtrer de cette bonace ?^-J'en sais rien, mais j'dis juste que j'me méfie de ce devin à la noix, c'est tout...^-Et comment on fait, pour la trouver, cette bague ?^-Bah, comme le poisson, on n'a qu'à la pêcher ! Ca mord à quel appât, une bague ? Des doigts ?~^^La proposition fait rire tout le monde. Pourtant, c'est une idée... Vous pourriez toujours essayer, peut-être qu'avec la chance, ou même les dieux derrière vous, vous arriveriez à la pêcher...";
		10: "Vous vous approchez des marins et leur racontez ce que vous avez vu. Malheureusement, ils semblent ne pas vous croire... ~Allez, t'as eu la berlue !^-C'était pas ce genre de breuvage qui t'as fait voir des choses, allez, avoue !^-T'es sûr que c'était pas plutôt Dionysos, que t'as vu ?~";
		}
		],
has animate pluralname concealed ;

Object rev "marin" pont2
	with told 0,
	description "Il semble absorbé dans la contemplation de la mer.",
	name 'marin' 'matelot' 'homme' 'moussaillon' 'reveur',
	before [; Push: pousmar(); rtrue;
		Tell, Ask: switch (self.told) {
			0: if (devin.told~=0) {self.told=1; "Vous vous approchez de l'homme et vous accoudez à côté de lui au bord du bateau.^^~Ca va ? faites-vous pour engager la conversation.^- Regarde par là, dit-il en désignant un endroit dans la mer de son doigt. Tu ne vois pas quelque chose qui brille ?~^^Vous regardez attentivement l'endroit qu'il vous désigne, mais vous ne voyez rien. Puis, brièvement, vous apercevez un vif éclat doré dans l'eau claire.^^~T'as vu ? Je me demande ce que c'était. En tout cas, je n'y vais pas, moi : l'eau est froide, ce matin...~";} else {"Vous ne voulez pas le déranger dans sa rêverie...";}
			1: "~Je me demande ce que c'était. En tout cas, je n'y vais pas, moi : l'eau est froide, ce matin...~";
			2: if (devin.told==0) {"~Eh ben alors toi, t'as pas froid aux yeux ! Bah, le jeu en valait la chandelle, après tout...~";} else {"Vous parlez avec le marin, en lui racontant ce que le devin vous avait demandé de chercher - et que la coupe que vous étiez allée chercher allait parfaitement convenir. Il fronce les sourcils, et vous dit d'un air désabusé :^^~De toute façon, ce gredin de Catirias te fait courir à droite et à gauche pour son breuvage, mais je suis persuadé qu'il a autant de dons de divination que toi et moi... D'ailleurs, entre ce qu'il va croire voir, ce qu'il va vouloir croire, ce qu'il imaginera, et ce qu'il te dira, si tu veux vraiment t'adresser aux dieux, ce serait peut-être même mieux que tu la boives toi-même, sa boisson !~";}
			3: "Vous parlez avec le marin et lui racontez ce que vous a dit le devin. Il prend cette nouvelle avec circonspection : ^^~Mouais... Je veux bien le croire. Mais bon, le connaissant, il a dû te raconter le résumé déformé... Je ne lui ferai pas totalement confiance, à ta place...^-Mais tu n'as pas une idée, pour la bague ?^-J'en sais rien... Je vois pas comment on pourrait la repêcher...~";
			10: "Vous racontez au marin que vous avez bu la boisson du devin, et ce que vous avez vu. Il sourit.^^~Je le savais : pas tellement besoin d'être devin, finalement, pour communiquer avec les dieux, hein ? Bon, ben au moins on sait pourquoi on en est là... Comment on va s'en tirer, ça c'est une autre affaire, mais bon...~";
			}
	],
has animate concealed;

Object capitaine "capitaine" chambrcap
	with told 0,
	description "C'est le capitaine du navire, un grand homme barbu et avec une voix de stentor. Pour l'heure, il étudie ses cartes de navigation.",
	name 'capitaine' 'chef' 'superieur',
	before [; Tell, Ask: switch(capitaine.told){
		0: "Vous vous raclez la gorge : le capitaine lève la tête de ses cartes. ~Oui ? Que voulez-vous ?^-Capitaine, je viens de consulter Catirias, à propos de la bonace, et il m'a dit que la cause en était divine...^-Explique-toi !~^^Vous lui racontez ce que le devin vous a dit. Il se gratte la barbe, puis fait : ~D'accord. Merci, au moins on sait pourquoi on en est là... C'est ce que je craignais, à vrai dire. Mais bon... Je n'ai pas la moindre idée de comment nous allons retrouver cette fameuse bague... Ecoutez, revenez me voir si vous avez une idée, je vais y réfléchir de mon côté, d'accord ?~";
		1: move canne to player; move fil to player ; "Vous vous raclez la gorge : le capitaine lève la tête de ses cartes. ~Oui ? Que voulez-vous ?^-Capitaine, je viens de... euh... de consulter Catirias...~ mentez-vous - mais c'est seulement pour qu'il vous croie.^~Qu'a-t-il dit ?^-Il a dit que la bonace est une punition d'Eole car il est fâché avec Athéna et ne veut pas que le vin arrive à bon port...~^Le capitaine a l'air embêté. ~C'est ce que je craignais, une punition divine...^-Capitaine, il a aussi dit qu'il nous rendrait du vent si on retrouvait une certaine bague lui appartenant... Mais celle-ci est on ne sait où sous l'eau...^-Alors, nous ne pouvons la retrouver !^-Mais après qu'il soit parti, Athéna m'a dit... enfin, à Catirias... qu'il fallait prendre une canne à pêche, et je pense qu'elle voulait dire qu'elle allait nous aider...~^Tout de suite, le visage du capitaine s'éclaire. ~Ah, enfin une bonne nouvelle ! Rendons grâce à Athéna, déesse de l'Intelligence... Tiens, prends ma canne à pêche !~ fait-il, en sortant une canne à pêche d'un coin de la pièce. ~Il manque un hameçon, mais ça ne devrait pas être très difficile à trouver, n'est pas ?~^^Vous remerciez le capitaine pour la canne à pêche ; il ne vous reste plus qu'à trouver un hameçon...";
		}
		],
has animate concealed ;

Object devin "devin" quart
	with told 0,
	description "Catirias, le devin, est assis ici. Il est un peu bizarre, et même suffisant, et vous ne l'aimez pas beaucoup, à dire vrai - vous avez déjà rencontré des charlatans plus crédibles que lui... Mais qui sait, il peut peut-être être utile, dans la situation où le bateau se trouve...",
	name 'devin' 'oracle' 'voyant' 'catirias',
	before [; Tell, Ask: switch(self.told){
			0: self.told=1; "Le devin tourne la tête vers vous, l'air de se réveiller soudainement.^^~Ah, bonjour, vous ! Alors, toujours pas de vent, n'est-ce pas ? La situation semble bloquée...^-Vous pensez pouvoir y faire quelque chose ? demandez-vous.^-Oh, oui, bien entendu... Enfin... Il serait peut-être possible que je puisse débloquer un tantinet la situation... Il est vrai que je pourrais demander aux dieux pourquoi une telle bonace s'abat sur nous... Après tout, seul moi ici est à même de connaître les volontés divines... Mais bon, ça ne va pas se faire tout seul, hein ! Il faut que vous me prépariez un breuvage approprié, afin de me permettre d'entrer en contact avec les dieux... Je vais vous dire de quoi j'ai besoin. Il me faudra... Un peu d'eau douce, dans laquelle vous mélangerez du vin, du miel, et un peu de levure... Il s'agit là d'une recette divine, qui permettra à mon esprit de s'élever jusqu'à la parole de l'Olympe... Ah, et vous mettrez tout ça dans une coupe dorée - je ne vais pas le boire dans mes mains, quand même ! Allez, mon garçon, allez me chercher tout ça, et vite, allez !~^^Vous n'y pouvez rien : vous avez envie de mettre des claques à ce devin. Mais le fait est que vous avez besoin de lui, et vous allez donc devoir céder à son caprice...";
			1: if (miel in coupe && eau in coupe && vin in coupe && levure in coupe && coupe in player) {dev(); rtrue;} else {"~Alors, mon garçon, vous avez trouvé ? Non ? Pas tout à fait, on dirait... Allez, ça n'est tout de même pas compliqué : du miel, de la levure, de l'eau et du vin, et tout cela dans une coupe dorée ! Dépêchons, allez, ne restez pas planté là !~";}
			2: "~Alors, mon garçon, vous comptez faire quelque chose ? Ah, heureusement que j'étais là pour révéler les vraies causes de cette bonace... Allez, faites quelque chose, nous n'allons pas rester bloqués par cette bonace éternellement, tout de même !~^^Toujours égal à lui même... C'est bien ce qui vous énerve.";
			10: "Le devin vous regarde, l'air énervé. ~J'ai appris que vous avez bu le breuvage que je vous avais demandé ! Malheureux ! Vous avez de la chance ! C'est très dangereux de vouloir jouer avec les dieux ! Vous ne vous rendez pas compte ! Inconscient ! Moi seul ici est à même de parler avec les dieux ! Ne le refaites plus jamais, c'est jouer avec le feu !~^^Mon oeil. C'est surtout qu'il est furieux que vous vous soyez passé de lui ; il a peur pour sa situation, oui : si n'importe qui peut communiquer avec les dieux, c'est la fin pour lui et son charlatanisme !";
				}
		],
has animate concealed ;

Object cuisinier "cuisinier" cuisine
	with told 0,
	description "Le cuistot est en train d'éplucher des légumes pour le repas du soir. Il semble concentré, mais vous pouvez toujours le déranger : il a bon caractère et toujours le sourire, et aime bien rigoler avec les hommes d'équipage.",
	name 'cuisinier' 'cuistot',
	before [; Tell, Ask: switch(self.told){
			0: if (devin.told==0) {"Le cuisinier vous accueille avec un grand sourire. ~Alors, comment ça va ?~ vous demande-t-il d'un air débonnaire.^^Vous passez quelques temps à discuter de la bonace ; et lui non plus n'est pas rassuré, d'après ce qu'il vous dit. ~D'autant plus que si vous autres continuez à manger comme ça, je n'aurai bientôt plus rien à vous faire manger, bande d'ogres !~ dit-il avec un grand éclat de rire.";} else {marins.told=1; self.told=1; "~Qu'est-ce qui t'amène, mon garçon ?~^Vous lui expliquez ce dont vous avez besoin. ~Ecoute, pour le miel et la levure, j'en fais mon affaire. Mais il va falloir que tu me rendes un petit service, d'accord ? Voilà : j'ai passé un de mes couteaux de cuisine et une louche à l'un des marins du bateau, il doit être en haut. Tu veux bien aller les chercher pour moi ? Merci.~^^Cette petite commission n'est rien, pensez-vous, et vous allez vous mettre à la recherche de ces ustensiles de ce pas !";}
			1: if (cout in player && louche in player) {
				if (coupe in player) {remove cout; remove louche; cuisinier.told=2; move miel to coupe; move levure to coupe; "Le cuisinier vous adresse un grand sourire :^^~Ah, merci, mon gars, merci beaucoup ! C'est très gentil ! Bon, ben je vais les laver, et puis je pourrai enfin m'en servir, pas trop tôt ! Tiens, voilà pour toi : prends ce miel, et un peu de levure !~^^Vous mettez ces deux ingrédients dans votre coupe et remerciez le cuistot.";}
				else {"~C'est gentil, mais tu sais, je préfère que tu me les rapporte quand tu auras trouvé quelque chose pour les mettre dedans... Allez, dépêche-toi de trouver un récipient, et reviens me voir !~";}
				}
			else {"~Alors, toujours pas retrouvés ? Continue à chercher, ils ne doivent pas être bien loin de toute façon !~";}
			2: "~Alors, la jeunesse, ça va toujours ?~";
			3: "Vous vous arrêtez discuter quelques instants avec le cuisinier, et vous lui racontez ce que le devin vous a dit. Il paraît rassuré. ~Ah, tout s'explique, alors ! Ah, les querelles de dieux... Bon, ben alors tout n'est pas perdu, il ne nous reste plus qu'à retrouver cette bague !~^^Le cuisinier est optimiste, mais on voit que ça n'est pas lui qui va la chercher, la bague...";
			10: "Vous vous arrêtez discuter quelques instants avec le cuisinier, et vous lui racontez ce que vous avez vous. Il fronce les sourcils : ~T'es sûr de toi, gamin ? Comment tu peux avoir vu quelque chose en n'étant pas devin ?~^^Vous avez beau lui assurer que c'était vrai, et que c'était l'effet du breuvage du devin, il reste circonspect... Bah, tant pis ; vous êtes sûr de ce que vous avez vu.";
				}
		],
has animate concealed ;

!==========================================================
! Routines

[ Initialise;
	give player light;
	lookmode=2;
	player.description = "Marin sur ce bateau depuis quelques temps déjà, vous avez déjà pas mal navigué sur les mers. Mais une bonace pareille, vous n'en aviez jamais encore vu... C'est un évènement assez extraordinaire pour faire se poser des questions à tout l'équipage, vous y compris...";
	location = pont1;
	print "Lorsque vous arrivez sur le pont supérieur, rien n'a vraiment changé depuis la veille. Pas un souffle de vent, la grande voile pend de son mât : le bateau n'avance pas. On croirait presque que l'ancre a été jetée. Une vraie bonace.^^Vous soupirez : déjà trois jours que le vent est quasiment inexistant. Dans cette partie de la Méditerranée, et en cette saison, c'est plutôt rare ; personne pas même les marins les plus expérimentés n'auraient pu prévoir ça. C'est un évènement assez exceptionnel, et étrange ; à croire que les dieux sont contre ce bateau.^^Sur le pont, les marins sont tous évidemment désoeuvrés. Certains sont à l'intérieur du bateau, mais d'autres sont sur le pont supérieur, profitant du soleil. Le capitaine, devant la situation, avait permis à tout le monde un peu de relâchement jusqu'à ce que le vent revienne ; les marins lui en étaient reconnaissants, et en avaient profité pour vaquer à diverses occupations : certains aidaient le cuisinier, d'autres jouaient aux dés, bref les marins se reposaient.^^";
	w8();
	print "Mais n'en étaient pas moins préoccupés par la situation. Tout le monde s'accordait à dire que ça n'était pas très normal. L'équipage ne se préoccupait pas tant pour les marchandises : c'était pour la plupart des amphores de vin destinées aux Panathénées qui devaient se dérouler prochainement à Athènes en l'honneur d'Athéna, fondatrice de la ville : elles ne risquaient pas de se dégrader et pouvaient supporter un peu de retard. L'ennuyeux était qu'elles arriveraient en retard au Pirée, et qu'il ne fallait pas trop traîner car Athènes attendait...^^Mais par-dessus tout, les hommes étaient préoccupés car le bateau n'avançait pas, et sans aucune raison valable. Et le fait que ça ne soit pas normal faisait peur aux hommes : ça pouvait ressembler à une colère des dieux, un châtiment divin ; et les hommes n'avaient aucune envie d'être victimes de l'ire des dieux. Il se murmurait que, pour une raison ou pour une autre, les dieux ne voulaient pas que le bateau arrive au Pirée à temps...^^Vous décidez alors d'employer votre temps libre à parcourir le bateau et à en découvrir un peu plus sur la situation.^^";
	w8();
];

[ AideSub ;
	style bold;
	print "^Divine bonace^";
	style roman;
	print "Marin à bord d'un bateau de la Grèce Antique victime d'une absence de vent aussi soudaine que mystérieuse, vous devez explorer le bateau et essayer d'en savoir plus sur la situation ; vous pourriez peut-être même résoudre le problème, qui sait...^^Bien que d'origine et d'inspiration grecque, ce jeu participe à la French Comp 2007.^";
];

[ plon ;

	print "Vous enjambez le rebord du bateau, décidé à plonger afin de récupérer l'objet qui brille au fond de l'eau.^^~Hé, mais qu'est-ce que tu fais ?^- Je vais voir ce que c'est, dites-vous au marin. Tu me remonteras ?^- Ben... Tu sais bien nager, j'espère ?! Ca peut être dangereux !^- Ne t'inquiète pas, faites-vous au marin. Et puis, tu vois un danger, avec la mer qu'on a aujourd'hui ?^- D'accord, si tu veux... Je vais chercher un cordage.~^^Vous vous placez en dehors du bateau, plaqué contre la coque, vous respirez un grand coup, puis vous sautez à la mer.^^";
	w8();
	print "Et comme attendu, elle est froide ; mais ça n'est pas bien grave, après tout.^^Vous nagez doucement vers le point que vous observiez depuis le bateau, et regardez : cela semble être vers ici. Vous prenez une grande respiration, puis vous plongez vers le fond de l'eau.^^C'est assez difficile de garder les yeux ouverts, mais vous y voyez suffisamment clair pour repérer l'objet : il est là, posé sur un rocher. C'est une coupe, ou quelque chose comme ça. Vous la prenez, et remontez vite à la surface.^^La première respiration vous fait l'effet d'un feu pénétrant dans vos poumons. Vous respirez bruyamment, clignez des yeux, et essayez de vous calmer.^^Depuis le bateau, vous pouvez entendre des clameurs et des applaudissements. Vous vous retournez : ce sont les marins, qui vous félicitent et vous encouragent depuis le bateau. Vous avez mis un peu d'animation dans leur matinée oisive, apparemment...^^";
	w8();
	print "Vous nagez vers le bateau, doucement car vous avez toujours la coupe à la main. Vous parvenez tant bien que mal à vous saisir de la corde, et vous remontez, tiré par les marins. Une fois sur le pont, ils vous congratulent, et vous donnent de grandes tapes dans le dos. Votre butin passe de main en main, et tout le monde contemple la coupe faite de métal précieux, probablement du bronze vu son poids. Pour autant, personne ne cherche à vous la voler : ils sont des amis et des camarades pour la plupart, et ne se risqueraient pas à vous dérober cette coupe, car en plus on finirait fatalement par retrouver le coupable. Par contre, ils espèrent bien que vous allez fêter ça avec eux !^";
	move coupe to player;
	rtrue;
];

[ pousmar ;
	print "Vous vous retournez pour regarder si quelqu'un peut vous voir : les joueurs de dés sont trop concentrés sur leur jeu.^^Vous vous approchez donc doucement du marin, et vous placez derrière lui. Puis d'un coup, vous le poussez et le renversez par-dessus bord. Il tombe dans l'eau en criant, dans un *plouf* sonore.^^Attirés par le bruit, les marins regardent le pauvre matelot se débattre dans l'eau. Vous estimez qu'il est alors temps de prendre la poudre d'escampette...^^";
	w8();
	print "Vous faites quelques pas en arrière - mais vous vous heurtez à quelqu'un. Vous vous retournez : c'est le capitaine en personne, et il n'a pas l'air de vouloir rire...^^Derrière vous, les marins se rapprochent et vous encerclent.^^~Mettez-moi celui-là aux fers !~ dit le capitaine.";
	w8();
	deadflag=1;
];

[ dev ;
	devin.told=2;
	marins.told=3;
	cuisinier.told=3;
	rev.told=3;
	remove coupe;
	print "~Alors,vous avez tout les ingrédients ?~ vous demande le devin.^^Vous lui tendez la coupe en bronze en acquiescant. Il regarde dedans, et sourit. ~Ca m'a l'air bon. A la vôtre !~^^Et il vide la coupe d'un trait.^^";
	w8();
	print "Le devin s'essuie les lèvres du revers de la main. Il fait claquer ses lèvres, et dit : ~Mmh. C'était très bon, en effet. Vous en avez d'autre ?~^^Vous le regardez d'un air interloqué. Se moquerait-il de vous ?^^";
	w8();
	print "Il se reprend bien vite. ~D'accord, d'accord, ça va, je vais vous dire, moi, ce que disent les dieux...~^^Il prend une profonde inspiration, ferme les yeux, semble se concentrer, met la tête dans sa main, dans une attitude de penseur. Puis, soudainement, il se met à trembler. Il est en transe.^^~Je vois... Je vois...~^^";
	w8();
	print "~Je suis sur le mont Olympe... Je vois... C'est un roi... C'est le roi... C'est Eole ! Le roi des Vents, il est devant moi ! Il y a aussi... C'est Athéna, je crois, elle a un casque... Oui, et ils disent que... Eole dit reproche quelque chose à Athéna, je ne comprends pas... Ils semblent en colère l'un contre l'autre... Eole demande des excuses, Athéna refuse... Elle est trop fière pour cela... Eole dit que puisque c'est comme ça, il va bloquer le bateau qui est censé apporter le vin aux fêtes d'Athéna - c'est le nôtre ! - afin d'empêcher les festivités !~^^C'était donc ça, une vengeance divine...^^";
	w8();
	print "~Athéna semble protester... Mais Eole refuse, et va se venger sur nous... Athéna proteste... Attendez... Eole laisse une chance au bateau, pour calmer Athéna... Il dit qu'il a perdu une bague dans la mer, à peu près dans ce secteur, elle doit être au fond de la mer quelque part... Il dit que si jamais l'équipage retrouve cette bague, alors ils pourront repartir !~^^";
	w8();
	print_ret "Le devin fronce les sourcils. Il semble se concentrer plus. ~Eole s'en va. Athéna... Elle dit quelque chose... A propos d'une canne à pêche...~ Il tremble, puis brusquement se détend. Il ouvre les yeux.^^~Et voilà ! Je n'ai pu en voir plus, mais bon, j'estime que c'est amplement suffisant pour vous, vous ne croyez pas ? Il ne vous reste plus qu'à trouver la bague ! De rien !~^^Vous protestez, mais vous savez que ça n'avancera à rien : Catirias est une vraie tête de mule.^^Il ne vous reste ~plus~ qu'à trouver cette bague, a-t-il dit. Autant trouver une aiguille dans une meule de foin... Eole le sait bien : vous n'avez aucune chance de trouver cette bague... Ah, les dieux sont exaspérants, quand ils se mettent à se quereller, comme ça...";
];

[ vision ;
	capitaine.told=1;
	devin.told=10;
	marins.told=10;
	cuisinier.told=10;
	rev.told=10;
	remove coupe;
	print "Vous regardez la coupe remplie du mélange dont le devin vous avait donné la recette. Vous pensez qu'après tout... Si ce charlatan de devin peut ~voir~ quelque chose en buvant ce breuvage... Alors pourquoi pas vous ?^^";
	w8();
	print "Vous buvez le contenu de la coupe cul sec. Le liquide est frais, sucré et doux. Vous profitez de chaque goutte.^^Juste après avoir bu ce breuvage, vous ne sentez rien, que le goût sucré qui vous reste dans la bouche. Puis tout d'un coup, vous voyez.^^";
	w8();
	print "Une sorte de brume vous enveloppe tout d'un coup. Vous ne voyez petit à petit plus rien de ce qui vous entoure. Vous ne bougez pas, et contemplez la brume : ça doit être, ça de voir quelque chose, d'entrer en contact avec les dieux...^^";
	w8();
	print "Vous voilà sur une montagne. Non, pas n'importe quelle montagne, en fait : vous êtes sur le mont Olympe. Un homme et une femme discutent un peu plus haut ; ils semblent vous rappeler quelque chose... Curieux, vous vous approchez.^^";
	w8();
	print "~Non, non et non ! Je ne m'excuserai pas ! Il n'y a pas de raisons !^-Ah, je vois, la déesse de la Sagesse a sa fierté... Elle fait des bêtises, elle me met en colère, et elle refuse d'admettre qu'elle s'est trompée !^-Je ne me suis pas trompée, Eole ! Je sais très bien ce que je fais ! C'est toi qui t'imagines que je l'ai fait pour te nuire, et qui le prend mal, alors que franchement, quand je l'ai fait, tu étais bien la dernière chose à laquelle je pouvais penser !~^^";
	w8();
	print "Mince. Eole et Athéna qui se disputent. A propos de quoi ? Pas moyen de le savoir. Ah, les querelles de dieux...^^~Encore pire ! Tu aggraves ton cas ! Tu aurais dû y penser ! Ma parole, mais es-tu bien la déesse de l'Intelligence ? Si c'est le cas, je n'ose imaginer la...^-Arrête, Eole ! Tu m'énerves !^-Eh bien moi, ça fait bien longtemps que je suis énervé après toi !~^^";
	w8();
	print "Vous n'osez vous manifester, de peur de subir un courroux divin...^^~Puisque c'est comme ça, je vais me venger !~ reprend le Roi des Vents. ~Dans pas longtemps, ce sont les Panathénées, c'est ça ? Je vois un bateau, en bas, chargé de t'apporter le vin...~^^Vous écarquillez les yeux. Ce bateau, c'est bien le vôtre ! ~Eh bien, puisque c'est comme ça, plus de vent pour lui ! Il n'avancera pas tant que tu ne m'auras pas fait des excuses !^-Eole, tu exagères ! Ce sont MES Panathénées, tu n'as pas le droit de gâcher ma fête !^-Je vais me gêner ! Ca t'apprendras, au moins la prochaine fois tu y réfléchiras à deux fois !~^^";
	w8();
	print "Athéna a l'air franchement embêtée. Vous décidez d'agir, et vous vous approchez.^^~Euh... Bonjour... Euh... C'est pas pour dire, mais... Je suis membre de l'équipage du bateau en question... Euh...~^^Eole vous toise d'un regard sévère, étonné, mais ne le laissant pas paraître. Athéna esquisse un sourire.^^~S'il vous plaît, faites la paix... Ca fait quand même un bout de temps qu'on est coincés sur le bateau, à s'ennuyer...~^^Vous n'en menez pas large : comment faire comprendre aux dieux que vous aimeriez bien qu'ils cessent leurs querelles sans les froisser ?^^";
	w8();
	print "Eole rit. ~Ah, ben il manque pas de cran, le mortel !^-Il a raison, Eole, on ferait mieux de faire la paix, hein ?^-Pas tant que tu ne m'auras pas présenté des excuses ! Ecoute bien, déesse de l'Intelligence, on va voir si tes mortels le sont autant que toi... Je vais vous donner une chance de vous en sortir, mortels ! J'ai perdu une bague, à peu près dans le même secteur que celui où vous êtes maintenant... Elle est tombée dans l'eau... Si vous êtes si malins, rapportez-la moi, et vous pourrez repartir !~^^Vous êtes estomaqué. Quelle mauvaise foi, pour un dieu ! ~Mais c'est pire que de chercher une aiguille dans une botte de foin !^-Tout a un prix, mortel !~ dit Eole en partant d'un rire mauvais. ~Allez, j'ai pas que ça à faire, moi !~^^Eole disparaît.^^";
	w8();
	print "Athéna semble lasse. ~Quel tête de mule... Bon, mortel, retourne sur ton bateau...~ Elle part, mais s'arrête au bout de quelques pas ; elle se retourne, et, en vous lançant un petit clin d'oeil, elle fait : ~Je serais toi, mortel, je prendrais une canne à pêche... M'est avis que la pêche va être bonne pour toi... Si tu vois ce que je veux dire...~^^Athéna s'en va, vous laissant confus.^^";
	w8();
	print_ret "La scène semble se dissoudre autour de vous... Quelques secondes encore, et vous êtes à nouveau sur le bateau, comme sorti d'un mauvais rêve...^^Ca a marché - preuve que le devin a autant de dons divinatoires que vous... Ainsi, vous savez pourquoi le bateau est bloqué dans cette bonace... Mais reste un écueil de taille : comment retrouver la bague ? Mais vous vous souvenez du clin d'oeil d'Athéna : c'est aussi la déesse de la ruse, après tout... Et d'après les dernières paroles qu'elle vous aie dites, vous pourriez compter sur une aide de sa part...";
];

[ fin ;
	print "Vous prenez le poisson, et vous assurez qu'il ne bouge plus. Et prenant votre courage à deux mains, en faisant la grimaçe, vous ouvrez le poisson.^^Après avoir cherché quelques temps, vous voyez une bague. Vous la prenez avec vous.^^Aussitôt une brume épaisse envahit le bateau et endort tout le monde, y compris vous...^^";
	w8();
	print "Quand vous vous réveillez, la brume s'est dissipée. Par contre, tout le monde dort encore. Vous essayez de réveiller les quelques marins sur le pont, mais sans succès.^^Vous regardez devant vous. Le bateau arrive vers une île, une île qui vous est inconnue ; vous pouvez y distinguer les contours d'une sorte de palais sur une colline. Le bateau semble aller vers cette île.^^Vous repensez à ce qui vous est arrivé : une brume épaisse, soudaine, et puis plus rien. Cette brume était vraiment sortie de nulle part. Se pourrait-il que... Peut-être qu'il s'agit... d'une brume arrivée autour du bateau par une intervention divine ?^^Le bateau vogue vers cette île : si ce sont les dieux qui en ont décidé ainsi, vous n'allez pas faire changer le bateau de direction.^^";
	w8();
	print "Quand vous accostez, des hommes sont sur le rivage, armés. Ils vous font signe et vous disent que le roi Eole vous attend.^^C'était donc ça... Les îles éoliennes...^^";
	w8();
	print "Quelques minutes après, escorté des gardes, vous arrivez au palais. On vous fait entrer dans ce lieu majestueux : c'est un immense palais de pierre, aux grandes colonnes et orné de peintures. L'une d'elle représente Eole, en tant que barbu aux joues gonflées, qui souffle pour faire avancer un bateau...^^Vous arrivez dans une grande pièce majestueuse : le roi Eole, roi des Vents, est sur son trône. Mais il n'a pas l'air très content.^^";
	w8();
	print "~Approche, mortel.~ vous dit-il.^^Vous grimpez les marches, saluez Eole, et vous lui remettez la bague. Il la sent. ~Je l'aurais parié... Elle sent le poisson. Pouah !~^^";
	w8();
	print "~Bien, mortel, tu as récupéré la bague que j'avais exigé... Je ne sais pas comment elle a pu atterrir entre tes mains...~^^Vous avez bien une petite idée, mais...^^Eole reprend : ~En vertu de notre arrangement avec Athéna, je crois que je suis obligé de vous rendre le vent...~^^Il n'a pas l'air enchanté - en même temps, il était à mille lieues de s'imaginer que vous la trouveriez aussi vite...^^";
	w8();
	print "Eole se penche vers vous et vous dit sur le ton de la confidence : ~Je ne te donne pas d'outre qui contiendrait les Vents, parce que la dernière fois, avec Ulysse, ça s'est mal terminé... Bref, toujours est-il que vous avez gagné : tu peux remonter sur ton bateau, mortel, il arrivera à bon port. Allez, ouste !~^^Vous vous courbez, remerciant le roi, et vous repartez en direction du bateau. Derrière vous, Eole, dépité, maugrée vaguement contre Athéna et les mortels...^^";
	w8();
	print "Tout de même... Il manque quelque chose. Vous avez le sentiment qu'il vous reste quelque chose à faire...^^";
	w8();
	print "Vous vous retournez, marchez vers Eole, qui lève un sourcil. ~Athéna s'excuse.~^^Ce qui était un gros coup de bluff, mais vous étiez déterminé à tenter.^^Eole se redresse sur son siège. ~Qu'en sais-tu ?^-Elle m'est apparue en rêve.^-Oui, ben tant qu'elle vient pas s'excuser en personne... Et qui me dis que tu dis la vérité, hein ?~ fait-il d'un ton bourru.^~Elle m'a dit qu'elle voudrait s'excuser auprès de vous, mais qu'elle ne veut pas le faire. Parce qu'elle est trop fière pour ça, et parce qu'elle ne veut pas céder et vous donner l'impression que vous la dominez. Pourtant, elle avait l'air sincèrement désolée, mais elle m'a dit qu'elle ne s'excusera pas dev...~^^Vous vous interrompez, l'air gêné. Comédie, mais c'est pour augmenter l'effet du bluff...^^";
	w8();
	print "~Eh bien ? Qu'elle ne s'excusera pas devant ?^-Euh... Je ne sais pas si je dois vous le dire, ô roi des Vents...^-Parle !~ crie Eole, qui est en train de s'énerver.^~Euh... Eh bien... Qu'elle ne s'excusera pas devant... Devant ce gros têtu ronchon aux grosses joues !~ finissez-vous par lâcher.^^Les épaules d'Eole s'affaissent. Vous avez soudainement peur d'être allé trop loin.^^";
	w8();
	print "Eole éclate de rire. Un grand rire grave, ni mauvais ni fâché. Ca a marché, semble-t-il...^^~Ah, fait-il quand il s'arrête de rire. Sacrée Athéna, va ! Ah, c'est bien elle, ça ! Ah, toujours drapée dans sa fierté, qui ne cède jamais, aussi guerrière qu'un homme... Ah là là... Sacrée elle...~^^";
	w8();
	print "Eole reprend : ~Mortel, merci de m'avoir dit ça... Je ne voulais pas rester trop fâché avec elle, mais étant donné qu'elle a encore plus de fierté que moi, je vais tout simplement passer l'éponge pour cette fois... On mettra les choses au point entre dieux responsables... Mortel, tu peux reprendre ta route, avec ma bénédiction, et celle d'Athéna !~^^Vous saluez bien bas le roi des Vents, et quittez son palais, le sourire aux lèvres...^^";
	w8();
	print "Lorsque vous revenez au bateau, une brume vous entoure, un peu moins longtemps cette fois. Quand elle se dissipe, vous pouvez voir le Pirée, à quelques heures de navigation à peine. L'équipage se réveille, et à la vision du Pirée et de la grande voile gonflée par le vent, laisse éclater sa joie.^^";
	w8();
	print "Un des marins, celui qui rêvassait quelques temps auparavant, vient vous voir. ~Alors, qu'est-ce qui s'est passé, à ton avis ? Tu sais ?~^^Vous souriez d'un sourire ambigu. ~Je te raconterai ça une fois à terre...~^^Vous savez vous faire discret...^^Mais cette histoire, vous la raconterez autour de vous, à vos enfants, et petits-enfants, et par le biais des aèdes, elle deviendra une légende de la Grèce Antique... L'Histoire ne dit pas votre nom, mais peu vous chaut : vous savez très bien, vous, ce que vous avez accompli...^^";
	w8();
	deadflag=2;
];

[ deroulSub;
	rfalse;
];

[ pechSub ;
	if (canne in player && fil in player && hamecon in player) {
		if (player in pont1) {"Vous lancez la canne à pêche, et attendez. Mais au bout de quelques minutes, vous devez vous résigner : ça ne mord pas, ici.";}
		else {
			if (player in pont2) {
				if (poisson in pont2) {"Vous venez de pêcher un poisson, ça ne sert à rien d'en pêcher un autre...";}
				else {move poisson to pont2; "Vous lancez votre ligne dans l'eau... Et vous ne tardez pas à sentir que quelque chose mord au bout ! Vous tirez la canne vers vous et remontez la ligne : oui, c'est bien un poisson qu'il y avait au bout. Vous le décrochez du hameçon, il tombe sur le pont, et après avoir frétillé quelques instants, il s'immobilise.";}
				}
			else {"Vous ne pouvez pas pêcher ici.";}
		}
	}
	"Vous n'avez rien pour pêcher.";
];

[ nagSub;
	if (player in pont1 || player in pont2 || (noun==mer && (player in pont1 || player in pont2))) {switch(rev.told){
			0: "Vous n'en voyez pas l'utilité ; en plus, elle doit être froide, en cette heure matinale...";
			1: rev.told=2; plon(); rtrue;
			2: "L'eau était assez froide, et vous n'avez pas tellement envie d'y retourner pour le plaisir.";
			}
			}
	"Vous ne pouvez pas faire cela.";
];

[ LicenseSub;

style bold;
print "Licence Creative Commons by-nc-nd ^pour : ~Divine bonace~ ^par : Hugo Labrande";
style roman;
print "^^Paternité-Pas d'Utilisation Commerciale-Pas de Modification 2.0 France^";
print "^";
print "Vous êtes libres : de reproduire, distribuer et communiquer cette création au public, selon les conditions suivantes :^";
print "^";
print "- Paternité. Vous devez citer le nom de l'auteur original de la manière indiquée par l'auteur de l'oeuvre ou le titulaire des droits qui vous confère cette autorisation (mais pas d'une manière qui suggérerait qu'ils vous soutiennent ou approuvent votre utilisation de l'oeuvre). ^";
print "^";
print "- Pas d'Utilisation Commerciale. Vous n'avez pas le droit d'utiliser cette création à des fins commerciales. ^";
print "^";
print "- Pas de Modification. Vous n'avez pas le droit de modifier, de transformer ou d'adapter cette création. ^";
print "^A chaque réutilisation ou distribution de cette création, vous devez faire apparaître clairement au public les conditions contractuelles de sa mise à disposition.^";
print "^";
print "Chacune de ces conditions peut être levée si vous obtenez l'autorisation du titulaire des droits sur cette oeuvre.^";
print "Rien dans ce contrat ne diminue ou ne restreint le droit moral de l'auteur ou des auteurs.^";
print "^";
print "Ce qui précède n'affecte en rien vos droits en tant qu'utilisateur (exceptions au droit d'auteur : copies réservées à l'usage privé du copiste, courtes citations, parodie...)^";
print "^";
print "http://creativecommons.org/licenses/by-nc-nd/2.0/fr/legalcode^";
];

!==========================================================
! Grammaire

Include "FrenchG";

Verb 'license' 'licence'
    *             -> License;

Verb 'derouler'
* noun		->deroul;

Verb 'aide'
*		->Aide;

Extend 'plonger' replace
*		->nag
* noun		->nag;

Extend 'nager'
*		->nag
* noun		->nag;

Verb 'pecher'
*		->pech;