!==========================================================
Constant Story "Un jeu d'enfant";
Constant Headline
 	"^Un jeu sur la guerre, par Hugo Labrande^";
Release 1;

Global enemy=0;
Global compteur=0;

Include "Parser";
Include "VerbLib";

[ w8 notNeeded;
  @read_char 1 notNeeded;
  rtrue;
];

!==========================================================
! Objets et lieux

Object champ "Champ de bataille"
	with description [; switch(enemy){
		0: "Tout est calme autour... Trop calme. De la fumée partout, des trous dans le sol, l'odeur de poudre... Nulle part où aller, nulle part où courir, et l'ennemi peut être n'importe où. Vous êtes sur vos gardes.";
		1: "Ils sont devant vous ! Les ennemis sont en ligne, prêts à tirer !";
		2: "Les ennemis sont tous morts, mais l'un d'eux a tiré une balle sur vous !";
		3: "Le champ de bataille est à nouveau silencieux. Vous êtes sur vos gardes, mais vous avez déjà battu plein d'ennemis, parce que vous êtes plus fort qu'eux !";
		4: "Un autre ennemi a surgi de la fumée. C'est Bruce Lee, et il fait des nunchakus ! Vous ne savez pas comment le battre, parce qu'il est très fort en kung-fu !";
		5: "Voilà, le champ de bataille est à nouveau vide. Peut-être pas pour très longtemps, mais vous êtes préparé.";
		6: "Venu pour vous combattre, le Bouffon Vert en personne vous regarde. Il pousse un ricanement en vous regardant et son visage est une horrible grimace.";
		7: "Le Bouffon Vert est reparti d'où il venait, parce que vous étiez trop fort ! Mais peut-être y'a-t-il encore d'autres ennemis !";
		8: "Voilà Dark Vador qui arrive ! Vous l'entendez respirer très fort, et il va sortir son sabre laser !";
		9: "Un péril plus grand se dirige vers vous : le bonhomme sept-heures ! Il est venu vous chercher, vous et Dark Vador... Mais il sera sûrement plus en colère face à vous...";
		}
		],
	n_to, s_to, e_to, w_to, in_to, out_to, nw_to, ne_to, se_to, sw_to "Vous savez que, où que vous alliez, la bataille continuera : restez donc bravement campé sur vos positions.",
	before [; Smell: if (noun==0) {"Ca sent la poudre, la bataille, la guerre. Vous connaissez cette odeur, à tel point que vous n'y faites plus attention.";}
		],
	each_turn [; testcompteur(); compteur++; rtrue;
		],
has ;

Object mitra "mitraillette"
	with description "Suzie, votre mitraillette bien-aimée. On peut se moquer du fait que vous lui ayez donné le même nom qu'une fille qui vous plaît, à l'école, mais de toute façon d'abord c'est même pas vrai, elle ne vous plaisait pas tant que ça, n'importe quoi.",
	name 'mitraillette' 'automatique' 'arme' 'suzie',
has ;

Object enem1 "ennemis"
	with description [; if (enemy==1) {"Ils sont beaucoup, ils sont armés, et ils viennent pour vous liquider ! Combattez !";} else {"Vous les avez tous eu, parce que vous êtes le plus fort !";}
		],
	name 'ennemis' 'ennemi' 'soldat' 'soldats',
has animate pluralname ;

Object enem2 "Bruce Lee"
	with description "C'est Bruce Lee, et il est très fort en kung-fu ! Il vous regarde, et fait un coup de pied dans l'air en criant ~Wahiaaaa !~",
	name 'bruce' 'lee' 'chinois' 'kung-fu',
	before [; Tirsur: "Bruce Lee, il est trop fort, il évite vos balles en faisant du kung-fu !";
		Attack: kungfu(); rtrue;
		],
has animate proper ;

Object enem3 "le Bouffon Vert"
	with description "C'est le Bouffon Vert ! Il est sur son planeur, et il va vous lancer des citrouilles explosantes si vous ne le battez pas !",
	name 'bouffon' 'vert' 'green' 'gobelin' 'ricanant',
	before [; Tirsur: "On dirait que le Bouffon Vert, il avait une armure et les balles elles rebondissaient sur lui !";
		Attack: planbouf(); rtrue;
		],
has animate proper ;

Object enem4 "Dark Vador"
	with description "Dark Vador, le plus grand méchant de la galaxie, vient vous combattre ! Il a déjà sorti son sabre laser !",
	name 'dark' 'vador' 'darth' 'vader',
	before [; Tirsur: "Dark Vador renvoie vos balles en les frappant avec son sabre laser.";
		],
has animate proper ;

Object enem5 "le bonhomme sept-heures"
	with description "Le bonhomme sept-heures ! C'est un vieux, et il vient chercher les enfants qui sont restés dehors après sept heures ! Et ensuite il les met dans son grand sac, et il va les jeter dans la rivière ! C'est le plus fort, vous le savez ! Inutile de lutter, vous devez vous rendre !",
	name 'bonhomme' 'sept-heures' 'sept' 'heures' 'papa',
	before [; Tirsur: "Ca va pas ? Vous vous prendriez une raclée !";
		],
has animate proper ;

Object balle "balle qui fonce vers vous"
	with description "La balle fonce vers vous à toute allure !",
	name 'balle' 'projectile',
	before [; Dodge: eviterballe(); rtrue;
		],
has ;

Object nunchaku "nunchaku"
	with description "C'est le nunchaku de Bruce Lee. Bruce Lee, il est très fort au nunchaku, et il les fait tourner autour de ses bras trop facilement. Ca fait des ~Whouw whouw~ tellement ça va vite, et Bruce Lee vous regarde d'un air méchant. Il est assez impressionnant.",
	name 'nunchaku' 'nunchak' 'arme',
	before [; Take: kungfu(); rtrue;
		],
has concealed ;

Object planeur "planeur"
	with description "C'est le planeur du Bouffon Vert, il crache de la fumée jaune. Le Bouffon Vert fait du surf dessus, et est prêt à vous battre !",
	name 'planeur' 'reacteur',
	before [; Attack: planbouf(); rtrue;
		],
has concealed ;

Object citroui "citrouilles"
	with description "C'est les citrouilles du Bouffon Vert, elles explosent en faisant de la fumée verte quand il les lance sur vous.",
	name 'citrouille' 'citrouilles' 'vertes' 'explosantes' 'explosante' 'grenade' 'grenade',
has concealed ;

Object sabrelas "sabre laser"
	with description "Dakr Vador a sorti son sabre laser rouge, et il va vous découper comme du saucisson si vous ne vous défendez pas !",
	name 'sabre' 'epee' 'laser' 'rouge',
has concealed ;

!==========================================================
! Routines

[ Initialise;
	give player light;
	player.description = "Brave aventurier, vous n'avez pas le temps de vous regarder : la mort guette, et il vous faut sans cesse vous battre !";
	location = champ;
	move mitra to player;
	"Essouflé, vous regardez autour de vous. La lande semble calme, un calme bien troublant. De la fumée, des vapeurs de soufre partout, des trous dans le sol. La bataille fut rude, et vous êtes maintenant. Mais vous n'avez pas peur. Vous savez que votre courage, votre héroïsme, et votre mitraillette vous feront survivre.";
];

[ testcompteur ;
	switch(enemy){
	0: if (compteur==1) {appenemi1(); rtrue;}
	1: if (compteur==2) {mort1(); rtrue;}
	2: if (compteur==1) {mort2(); rtrue;}
	3: if (compteur==1) {appenemi2(); rtrue;}
	4: if (compteur==2) {mort3(); rtrue;}
	5: if (compteur==1) {appenemi3(); rtrue;}
	6: if (compteur==2) {mort4(); rtrue;}
	7: if (compteur==1) {appenemi4(); rtrue;}
	8: if (compteur==1) {appenemi5(); rtrue;}
	9: if (compteur==2) {fin(); rtrue;}
	}
];

[ appenemi1 ;
	compteur=0; enemy++;
	move enem1 to champ;
	print "Soudain, vous entendez des cris. Vous sursautez, et vous crispez d'un coup. Ce cri semble venir de devant, mais la fumée vous empêche de voir à plus de vingt mètres.";
	w8();
	print "^^Des bruits de pas. Des hommes qui courent. Des tintements, comme des... Comme des mitraillettes en bandoulière !";
	w8();
	"^^Les ennemis arrivent ! Ils viennent pour vous tuer ! Vite, il faut combattre !";
];

[ mortenem1 ;
	 compteur=0; enemy++;
	move balle to champ;
	print "Vous brandissez votre mitraillette vers les ennemis, et vous criez : ~A l'attaque ! Pas de quartier !~";
	w8();
	print "^^Vous tirez sur les ennemis. Tacatacatacatacatac ! Ils tombent les uns après les autres ! Vous continuez à tirer ! Paf ! Bang ! Il met la main à sa poitrine, et crie ~Ah ! Je suis mort !~";
	w8();
	print "^^Vous les avez tous eu ! Grâce à votre fidèle Suzie, ils sont tous morts ! Yah !";
	w8();
	"^^^Oui, mais on dirait que y'en avait un qui n'était pas tout à fait mort ! Et juste avant de mourir, il vous tire une dernière balle dessus !";
];

[ eviterballe ;
	 compteur=0; enemy++;
	remove enem1; remove balle;
	"Oui, mais on dirait que la balle, vous l'évitez en sautant sur le côté. D'ailleurs, vous tombez par terre. Mais bon au moins vous n'êtes pas mort !";
];

[ appenemi2 ;
	 compteur=0; enemy++;
	move enem2 to champ;
	"Mais devant vous soudain apparaît un autre méchant ! Et c'est Bruce Lee ! Il est super fort en kung-fu, et il est venu vous taper !";
];

[ kungfu ;
	if (enemy==4) {
	compteur=0; enemy++;
	remove enem2;
	"De toute façon, vous êtes plus fort que Bruce Lee ! Il se défend bien, mais vous lui faites un Super kick de la mort qui tue et Bruce Lee, il est mort !";
	}
	else "Ca sert à rien.";
];

[ appenemi3 ;
	compteur=0; enemy++;
	move enem3 to champ;
	"Soudain le Bouffon Vert arrive ! C'est lui, l'ennemi de Spiderman ! Et il est vraiment super méchant ! Il faut que vous le combattiez !";
];

[ planbouf ;
	compteur=0; enemy++;
	remove enem3;
	"Le Bouffon Vert, de toute façon, c'est un bouffon ! Vous lui tapez dans son planeur, et vous lui cassez net ! Alors le Bouffon Vert déguerpit parce qu'il voit que vous êtes trop fort !";
];

[ appenemi4 ;
	compteur=0; enemy++;
	move enem4 to champ;
	"Mais voilà qu'arrive Dark Vador ! Il respire très fort, et il est très menaçant ! Il a un super sabre laser rouge qui fait un bruit électrique ! Comment se défendre face à lui ?";
];

[ appenemi5 ;
	compteur=0; enemy++;
	move enem5 to champ;
	"Dark Vador est certes très très fort, mais vous voyez derrière lui, au loin, un ennemi encore plus fort qui s'approche ! C'est lui ! C'est le mythique, l'imbattable bonhomme sept-heures ! Il vient chercher les enfants pas sages, ceux qui restent dehors après sept heures, et après il les mange !^^Vous le pointez du doigt à Dark Vador : ~Regarde, le bonhomme sept-heures !^-Zut, déjà ! Bon, alors finissons-en vite !~";
];

[ fin ;
	print "Dark Vador vous regarde et fait d'une voix super grave : ~Cette fois, c'est fini. Je vais te découper en rondelles. Kévin, je suis ton père.~";
	w8();
	print "^^Le bonhomme sept-heures s'interpose. ~Non, désolé, Kévin, mais c'est moi, ton père. Maintenant tu me suis, et tu rentres à la maison.^-Mais, m'sieur ! S'il vous plaît ! fait Ludovic. On s'amuse, il m'a tué quand j'étais Bruce Lee, alors j'ai démouru, et j'étais le Bouffon Vert, mais là j'étais Dark Vador, et...^-Oui, ben vous continuerez demain, hein ? Mais là, il commence à faire noir, il est sept heures et à sept heures on rentre, n'est-ce pas Kévin ?~^Vous ne répondez pas, et vous baissez les yeux en grommelant. ~Allez, viens, on rentre.^-Ooh, pfouh ! fait Ludovic.^-Eh oui, Ludovic, mais faut bien à un moment s'arrêter de jouer ! Allez, vous vous voyez demain à l'école.^-Ouais... Bon ben, salut Kévin...^-Salut Ludo. A demain !~";
	w8();
	print "^^Ludovic retourne vers chez lui, et vous suivez votre papa en traînant les pieds.^~C'est pas juste, dites-vous. On s'amusait bien !^-Je sais, bonhomme, je sais. Mais il fait nuit, et il faut rentrer à la maison...^-Ouais...~^^D'abord, vous continuerez à jouer demain, et puis Ludovic il a qu'à bien se tenir, parce que demain, c'est vous qui faites les méchants !!";
	w8();
	deadflag=2;
];

[ mort1 ;
	print "Vous n'êtes pas assez rapide ! Les soldats vous tirent dessus et vous êtes touché !";
	w8();
	deadflag=1;
];

[ mort2 ;
	print "Vous n'arrivez pas à arrêter la balle et elle vous tue !";
	w8();
	deadflag=1;
];

[ mort3 ;
	print "Bruce Lee est trop fort : il vous met des baffes, puis il crie ~Banzaï !!~ et il vous fait un coup de pied rotatif de la mort !";
	w8();
	deadflag=1;
];

[ mort4 ;
	print "Le Bouffon vert vous lance une grenade-citrouille ! Vous essayez de la relancer, mais elle vous explose dessus !";
	w8();
	deadflag=1;
];

[ tirSub;
	switch(enemy){
	1: mortenem1(); rtrue;
	4: "Bruce Lee, il est trop fort, il évite vos balles en faisant du kung-fu !";
	6: "On dirait que le Bouffon Vert, il avait une armure et les balles elles rebondissaient sur lui !";
	8: "Dark Vador renvoie vos balles en les frappant avec son sabre laser.";
	9: "Ca va pas ? Vous vous prendriez une raclée !";
	}
	"Tirer dans le vide ne sert à rien.";
];

[ tirsurSub;
	"Vous avez pas le droit de tirer sur ça !";
];

[ tiravecSub;
	"Vous avez pas le droit de tirer avec ça !";
];

[ dodgeSub;
	"Vous ne pouvez pas éviter ça, sinon c'est pas du jeu !";
];

[ kungfuSub ;
	kungfu(); rtrue;
];

!==========================================================
! Grammaire

Include "FrenchG";

Extend 'tirer' replace
*			-> tir
* 'sur' noun		-> tirsur
* 'avec' noun		-> tiravec;

Verb 'eviter'
* noun			-> dodge;

Extend 'faire'
* 'du kung-fu'		-> kungfu;